WebDAV System Module

Modules/System/WebDAV/README.md

@@ -0,0 +1,3 @@
+# WebDAV
+
+This module provides functions to interact with WebDAV API

Modules/System/WebDAV/app.json

@@ -0,0 +1,27 @@
+{
+    "id":  "199527d2-53dd-48e1-8732-8850d4f9e45b",
+    "name":  "WebDAV",
+    "publisher":  "Microsoft",
+    "brief":  "Connect to WebDAV.",
+    "description":  "Provides a set of AL functionality and Helper libraries to make use of WebDAV API",
+    "version":  "21.0.0.0",
+    "privacyStatement":  "https://go.microsoft.com/fwlink/?linkid=724009",
+    "EULA":  "https://go.microsoft.com/fwlink/?linkid=2009120",
+    "help":  "https://go.microsoft.com/fwlink/?linkid=2103698",
+    "url":  "https://go.microsoft.com/fwlink/?linkid=724011",
+    "logo":  "",
+    "dependencies":  [
+
+    ],
+    "screenshots":  [],
+    "platform":  "21.0.0.0",
+    "application": "21.0.0.0",
+    "idRanges":  [
+        {
+            "from":  5678,
+            "to":  5699
+        }
+    ],
+    "target":  "OnPrem",
+    "contextSensitiveHelpUrl":  "/dynamics365/business-central/"
+}

Modules/System/WebDAV/src/Authorization/WebDAVAuthorization.Interface.al

@@ -0,0 +1,4 @@
+interface "WebDAV Authorization"
+{
+    procedure Authorize(var HttpRequestMessage: HttpRequestMessage);
+}

Modules/System/WebDAV/src/Authorization/WebDAVBasicAuthImpl.Codeunit.al

@@ -0,0 +1,30 @@
+codeunit 5681 "WebDAV Basic Auth. Impl." implements "WebDAV Authorization"
+{
+    Access = Internal;
+
+    var
+        [NonDebuggable]
+        AuthorizationString: Text;
+
+    [NonDebuggable]
+    procedure Authorize(var HttpRequestMessage: HttpRequestMessage);
+    var
+        Headers: HttpHeaders;
+    begin
+        HttpRequestMessage.GetHeaders(Headers);
+        Headers.Remove('Authorization');
+        Headers.Add('Authorization', AuthorizationString);
+
+        Headers.Remove('Translate');
+        Headers.Add('Translate', 'F');
+    end;
+
+
+    [NonDebuggable]
+    procedure SetUserNameAndPassword(Username: Text; Password: Text)
+    var
+        Base64Convert: Codeunit "Base64 Convert";
+    begin
+        AuthorizationString := 'Basic ' + Base64Convert.ToBase64(Username + ':' + Password);
+    end;
+}

Modules/System/WebDAV/src/Authorization/WebDAVBasicAuthorization.Codeunit.al

@@ -0,0 +1,13 @@
+codeunit 5680 "WebDAV Basic Authorization"
+{
+    Access = Public;
+
+    procedure GetWebDAVBasicAuth(Username: Text; Password: Text): Interface "WebDAV Authorization"
+    var
+        WebDAVBasicAuthImpl: Codeunit "WebDAV Basic Auth. Impl.";
+    begin
+        WebDAVBasicAuthImpl.SetUserNameAndPassword(Username, Password);
+        Exit(WebDAVBasicAuthImpl);
+    end;
+
+}

Modules/System/WebDAV/src/Helper/WebDAVDiagnostics.Codeunit.al

@@ -0,0 +1,77 @@
+// ------------------------------------------------------------------------------------------------
+// Copyright (c) Microsoft Corporation. All rights reserved.
+// Licensed under the MIT License. See License.txt in the project root for license information.
+// ------------------------------------------------------------------------------------------------
+
+/// <summary>
+/// Stores detailed information about failed api call
+/// </summary>
+codeunit 5685 "WebDAV Diagnostics" implements "HTTP Diagnostics"
+{
+    Access = Internal;
+
+    var
+        ErrorMessage, ResponseReasonPhrase : Text;
+        HttpStatusCode, RetryAfter : Integer;
+        SuccessStatusCode: Boolean;
+
+    /// <summary>
+    /// Gets reponse details.
+    /// </summary>
+    /// <returns>HttpResponseMessage.IsSuccessStatusCode</returns>
+    [NonDebuggable]
+    procedure IsSuccessStatusCode(): Boolean
+    begin
+        exit(SuccessStatusCode);
+    end;
+
+    /// <summary>
+    /// Gets response details.
+    /// </summary>
+    /// <returns>HttpResponseMessage.StatusCode</returns>
+    [NonDebuggable]
+    procedure GetHttpStatusCode(): Integer
+    begin
+        exit(HttpStatusCode);
+    end;
+
+    /// <summary>
+    /// Gets response details.
+    /// </summary>
+    /// <returns>Retry-after header value</returns>
+    [NonDebuggable]
+    procedure GetHttpRetryAfter(): Integer
+    begin
+        exit(RetryAfter);
+    end;
+
+    /// <summary>
+    /// Gets reponse details
+    /// </summary>
+    /// <returns>Error message</returns>
+    [NonDebuggable]
+    procedure GetErrorMessage(): Text
+    begin
+        exit(ErrorMessage);
+    end;
+
+    /// <summary>
+    /// Gets response details.
+    /// </summary>
+    /// <returns>HttpResponseMessage.ResponseReasonPhrase</returns>
+    [NonDebuggable]
+    procedure GetResponseReasonPhrase(): Text
+    begin
+        exit(ResponseReasonPhrase);
+    end;
+
+    [NonDebuggable]
+    internal procedure SetParameters(NewIsSuccesss: Boolean; NewHttpStatusCode: Integer; NewResponseReasonPhrase: Text; NewRetryAfter: Integer; NewErrorMessage: Text)
+    begin
+        SuccessStatusCode := NewIsSuccesss;
+        HttpStatusCode := NewHttpStatusCode;
+        ResponseReasonPhrase := NewResponseReasonPhrase;
+        RetryAfter := NewRetryAfter;
+        ErrorMessage := NewErrorMessage;
+    end;
+}

Modules/System/WebDAV/src/Helper/WebDAVHttpContent.Codeunit.al

@@ -0,0 +1,76 @@
+// ------------------------------------------------------------------------------------------------
+// Copyright (c) Microsoft Corporation. All rights reserved.
+// Licensed under the MIT License. See License.txt in the project root for license information.
+// ------------------------------------------------------------------------------------------------
+
+codeunit 5686 "WebDAV Http Content"
+{
+    Access = Internal;
+
+    var
+        HttpContent: HttpContent;
+        ContentLength: Integer;
+        ContentType: Text;
+        RequestDigest: Text;
+
+    procedure FromFileInStream(var ContentInStream: Instream)
+    begin
+        HttpContent.WriteFrom(ContentInStream);
+        ContentLength := GetContentLength(ContentInStream);
+    end;
+
+    procedure FromText(Content: Text)
+    var
+        InStream: InStream;
+    begin
+        HttpContent.WriteFrom(Content);
+        HttpContent.ReadAs(InStream);
+        ContentLength := GetContentLength(InStream);
+    end;
+
+    procedure FromXML(XMLDoc: XmlDocument)
+    var
+        RequestText: Text;
+    begin
+        XMLDoc.WriteTo(RequestText);
+        HttpContent.WriteFrom(RequestText);
+        ContentLength := StrLen(RequestText);
+    end;
+
+    procedure GetContent(): HttpContent
+    begin
+        exit(HttpContent);
+    end;
+
+    procedure GetContentLength(): Integer
+    begin
+        exit(ContentLength);
+    end;
+
+    procedure GetContentType(): Text
+    begin
+        exit(ContentType);
+    end;
+
+    // TODO DIGEST??
+    procedure SetRequestDigest(RequestDigestValue: Text)
+    begin
+        RequestDigest := RequestDigestValue;
+    end;
+
+    procedure GetRequestDigest(): Text;
+    begin
+        exit(RequestDigest);
+    end;
+
+    local procedure GetContentLength(var SourceInStream: InStream) Length: Integer
+    var
+        MemoryStream: DotNet MemoryStream;
+    begin
+        MemoryStream := MemoryStream.MemoryStream();
+        CopyStream(MemoryStream, SourceInStream);
+        Length := MemoryStream.Length;
+        Clear(SourceInStream);
+    end;
+
+}

Modules/System/WebDAV/src/Helper/WebDAVOperationResponse.Codeunit.al

@@ -0,0 +1,99 @@
+// ------------------------------------------------------------------------------------------------
+// Copyright (c) Microsoft Corporation. All rights reserved.
+// Licensed under the MIT License. See License.txt in the project root for license information.
+// ------------------------------------------------------------------------------------------------
+
+codeunit 5684 "WebDAV Operation Response"
+{
+    Access = Internal;
+
+    [NonDebuggable]
+    [TryFunction]
+    internal procedure GetResultAsText(var Result: Text);
+    var
+        ResultInStream: InStream;
+    begin
+        TempBlobContent.CreateInStream(ResultInStream);
+        ResultInStream.Read(Result);
+    end;
+
+    [NonDebuggable]
+    [TryFunction]
+    internal procedure GetResultAsStream(var ResultInStream: InStream)
+    begin
+        TempBlobContent.CreateInStream(ResultInStream);
+    end;
+
+    [NonDebuggable]
+    internal procedure SetHttpResponse(HttpResponseMessage: HttpResponseMessage)
+    var
+        ContentOutStream: OutStream;
+        ContentInStream: InStream;
+    begin
+
+        TempBlobContent.CreateOutStream(ContentOutStream);
+        HttpResponseMessage.Content().ReadAs(ContentInStream);
+        CopyStream(ContentOutStream, ContentInStream);
+        HttpHeaders := HttpResponseMessage.Headers();
+
+        WebDAVDiagnostics.SetParameters(HttpResponseMessage.IsSuccessStatusCode, HttpResponseMessage.HttpStatusCode, HttpResponseMessage.ReasonPhrase, GetRetryAfterHeaderValue(), GetErrorDescription());
+    end;
+
+    [NonDebuggable]
+    internal procedure SetHttpResponse(ResponseContent: Text; ResponseHttpHeaders: HttpHeaders; ResponseHttpStatusCode: Integer; ResponseIsSuccessStatusCode: Boolean; ResponseReasonPhrase: Text)
+    var
+        ContentOutStream: OutStream;
+    begin
+        TempBlobContent.CreateOutStream(ContentOutStream);
+        ContentOutStream.WriteText(ResponseContent);
+        HttpHeaders := ResponseHttpHeaders;
+        WebDAVDiagnostics.SetParameters(ResponseIsSuccessStatusCode, ResponseHttpStatusCode, ResponseReasonPhrase, GetRetryAfterHeaderValue(), GetErrorDescription());
+    end;
+
+    [NonDebuggable]
+    internal procedure GetHeaderValueFromResponseHeaders(HeaderName: Text): Text
+    var
+        Values: array[100] of Text;
+    begin
+        if not HttpHeaders.GetValues(HeaderName, Values) then
+            exit('');
+        exit(Values[1]);
+    end;
+
+    [NonDebuggable]
+    internal procedure GetRetryAfterHeaderValue() RetryAfter: Integer;
+    var
+        HeaderValue: Text;
+    begin
+        HeaderValue := GetHeaderValueFromResponseHeaders('Retry-After');
+        if HeaderValue = '' then
+            exit(0);
+        if not Evaluate(RetryAfter, HeaderValue) then
+            exit(0);
+    end;
+
+    [NonDebuggable]
+    local procedure GetErrorDescription(): Text
+    var
+        Result: Text;
+        JObject: JsonObject;
+        JToken: JsonToken;
+    begin
+        GetResultAsText(Result);
+        if Result <> '' then
+            if JObject.ReadFrom(Result) then
+                if JObject.Get('error_description', JToken) then
+                    exit(JToken.AsValue().AsText());
+    end;
+
+    [NonDebuggable]
+    internal procedure GetDiagnostics(): Interface "HTTP Diagnostics"
+    begin
+        exit(WebDAVDiagnostics);
+    end;
+
+    var
+        TempBlobContent: Codeunit "Temp Blob";
+        WebDAVDiagnostics: Codeunit "WebDAV Diagnostics";
+        HttpHeaders: HttpHeaders;
+}