Initial import of original channels.

101629_na3n.mod/101629_na3n.mod

@@ -0,0 +1,132 @@
+TITLE na3
+: Na current 
+: modified from Jeff Magee. M.Migliore may97
+: added sh to account for higher threshold M.Migliore, Apr.2002
+
+NEURON {
+	SUFFIX na3
+	USEION na READ ena WRITE ina
+	RANGE  gbar, ar, sh
+	GLOBAL minf, hinf, mtau, htau, sinf, taus,qinf, thinf
+}
+
+PARAMETER {
+	sh   = 24	(mV)
+	gbar = 0.010   	(mho/cm2)	
+
+	tha  =  -30	(mV)		: v 1/2 for act	
+	qa   = 7.2	(mV)		: act slope (4.5)		
+	Ra   = 0.4	(/ms)		: open (v)		
+	Rb   = 0.124 	(/ms)		: close (v)		
+
+	thi1  = -45	(mV)		: v 1/2 for inact 	
+	thi2  = -45 	(mV)		: v 1/2 for inact 	
+	qd   = 1.5	(mV)	        : inact tau slope
+	qg   = 1.5      (mV)
+	mmin=0.02	
+	hmin=0.5			
+	q10=2
+	Rg   = 0.01 	(/ms)		: inact recov (v) 	
+	Rd   = .03 	(/ms)		: inact (v)	
+	qq   = 10        (mV)
+	tq   = -55      (mV)
+
+	thinf  = -50 	(mV)		: inact inf slope	
+	qinf  = 4 	(mV)		: inact inf slope 
+
+        vhalfs=-60	(mV)		: slow inact.
+        a0s=0.0003	(ms)		: a0s=b0s
+        zetas=12	(1)
+        gms=0.2		(1)
+        smax=10		(ms)
+        vvh=-58		(mV) 
+        vvs=2		(mV)
+        ar=1		(1)		: 1=no inact., 0=max inact.
+	ena		(mV)            : must be explicitly def. in hoc
+	celsius
+	v 		(mV)
+}
+
+
+UNITS {
+	(mA) = (milliamp)
+	(mV) = (millivolt)
+	(pS) = (picosiemens)
+	(um) = (micron)
+} 
+
+ASSIGNED {
+	ina 		(mA/cm2)
+	thegna		(mho/cm2)
+	minf 		hinf 		
+	mtau (ms)	htau (ms) 	
+	sinf (ms)	taus (ms)
+}
+
+
+STATE { m h s}
+
+BREAKPOINT {
+        SOLVE states METHOD cnexp
+        thegna = gbar*m*m*m*h*s
+	ina = thegna * (v - ena)
+} 
+
+INITIAL {
+	trates(v,ar,sh)
+	m=minf  
+	h=hinf
+	s=sinf
+}
+
+
+FUNCTION alpv(v(mV)) {
+         alpv = 1/(1+exp((v-vvh-sh)/vvs))
+}
+
+FUNCTION alps(v(mV)) {  
+  alps = exp(1.e-3*zetas*(v-vhalfs-sh)*9.648e4/(8.315*(273.16+celsius)))
+}
+
+FUNCTION bets(v(mV)) {
+  bets = exp(1.e-3*zetas*gms*(v-vhalfs-sh)*9.648e4/(8.315*(273.16+celsius)))
+}
+
+LOCAL mexp, hexp, sexp
+
+DERIVATIVE states {   
+        trates(v,ar,sh)      
+        m' = (minf-m)/mtau
+        h' = (hinf-h)/htau
+        s' = (sinf - s)/taus
+}
+
+PROCEDURE trates(vm,a2,sh2) {  
+        LOCAL  a, b, c, qt
+        qt=q10^((celsius-24)/10)
+	a = trap0(vm,tha+sh2,Ra,qa)
+	b = trap0(-vm,-tha-sh2,Rb,qa)
+	mtau = 1/(a+b)/qt
+        if (mtau<mmin) {mtau=mmin}
+	minf = a/(a+b)
+
+	a = trap0(vm,thi1+sh2,Rd,qd)
+	b = trap0(-vm,-thi2-sh2,Rg,qg)
+	htau =  1/(a+b)/qt
+        if (htau<hmin) {htau=hmin}
+	hinf = 1/(1+exp((vm-thinf-sh2)/qinf))
+	c=alpv(vm)
+        sinf = c+a2*(1-c)
+        taus = bets(vm)/(a0s*(1+alps(vm)))
+        if (taus<smax) {taus=smax}
+}
+
+FUNCTION trap0(v,th,a,q) {
+	if (fabs(v-th) > 1e-6) {
+	        trap0 = a * (v - th) / (1 - exp(-(v - th)/q))
+	} else {
+	        trap0 = a * q
+ 	}
+}	
+
+

101629_na3n.mod/Readme.md

@@ -0,0 +1,19 @@
+# ICGenealogy Channel: 101629\_na3n.mod
+
+## Details
+
+Name | Description
+---- | -----------
+ModelDB id | [101629](http://senselab.med.yale.edu/ModelDB/ShowModel.cshtml?model=101629)
+ICG id | [13](http://icg.neurotheory.ox.ac.uk/channels/2/13)
+ICG Class | [Na](http://icg.neurotheory.ox.ac.uk/channels/2)
+
+## Description
+
+This is a single channel model file that was originally part of a [published model on the ModelDB website](http://senselab.med.yale.edu/mModelDB/ShowModel.cshtml?model=101629).
+
+The file [101629\_na3n.mod](101629_na3n.mod) was extrated from [the ModelDB repository](http://senselab.med.yale.edu/ModelDB/ShowModel.cshtml?model=101629), and committed in its original form.
+
+## Usage
+
+See the [icg-channel super-repository](https://github.com/icgenealogy/icg-channels) for more information.

101629_naxn.mod/101629_naxn.mod

@@ -0,0 +1,101 @@
+TITLE nax
+: Na current for axon. No slow inact.
+: M.Migliore Jul. 1997
+: added sh to account for higher threshold M.Migliore, Apr.2002
+
+NEURON {
+	SUFFIX nax
+	USEION na READ ena WRITE ina
+	RANGE  gbar, sh
+	GLOBAL minf, hinf, mtau, htau,thinf, qinf
+}
+
+PARAMETER {
+	sh   = 8	(mV)
+	gbar = 0.010   	(mho/cm2)	
+
+	tha  =  -30	(mV)		: v 1/2 for act	
+	qa   = 7.2	(mV)		: act slope (4.5)		
+	Ra   = 0.4	(/ms)		: open (v)		
+	Rb   = 0.124 	(/ms)		: close (v)		
+
+	thi1  = -45	(mV)		: v 1/2 for inact 	
+	thi2  = -45 	(mV)		: v 1/2 for inact 	
+	qd   = 1.5	(mV)	        : inact tau slope
+	qg   = 1.5      (mV)
+	mmin=0.02	
+	hmin=0.5			
+	q10=2
+	Rg   = 0.01 	(/ms)		: inact recov (v) 	
+	Rd   = .03 	(/ms)		: inact (v)	
+
+	thinf  = -50 	(mV)		: inact inf slope	
+	qinf  = 4 	(mV)		: inact inf slope 
+
+	ena		(mV)            : must be explicitly def. in hoc
+	celsius
+	v 		(mV)
+}
+
+
+UNITS {
+	(mA) = (milliamp)
+	(mV) = (millivolt)
+	(pS) = (picosiemens)
+	(um) = (micron)
+} 
+
+ASSIGNED {
+	ina 		(mA/cm2)
+	thegna		(mho/cm2)
+	minf 		hinf 		
+	mtau (ms)	htau (ms) 	
+}
+
+
+STATE { m h}
+
+BREAKPOINT {
+        SOLVE states METHOD cnexp
+        thegna = gbar*m*m*m*h
+	ina = thegna * (v - ena)
+} 
+
+INITIAL {
+	trates(v,sh)
+	m=minf  
+	h=hinf
+}
+
+DERIVATIVE states {   
+        trates(v,sh)      
+        m' = (minf-m)/mtau
+        h' = (hinf-h)/htau
+}
+
+PROCEDURE trates(vm,sh2) {  
+        LOCAL  a, b, qt
+        qt=q10^((celsius-24)/10)
+	a = trap0(vm,tha+sh2,Ra,qa)
+	b = trap0(-vm,-tha-sh2,Rb,qa)
+	mtau = 1/(a+b)/qt
+        if (mtau<mmin) {mtau=mmin}
+	minf = a/(a+b)
+
+	a = trap0(vm,thi1+sh2,Rd,qd)
+	b = trap0(-vm,-thi2-sh2,Rg,qg)
+	htau =  1/(a+b)/qt
+        if (htau<hmin) {htau=hmin}
+	hinf = 1/(1+exp((vm-thinf-sh2)/qinf))
+}
+
+FUNCTION trap0(v,th,a,q) {
+	if (fabs(v-th) > 1e-6) {
+	        trap0 = a * (v - th) / (1 - exp(-(v - th)/q))
+	} else {
+	        trap0 = a * q
+ 	}
+}	
+
+
+

101629_naxn.mod/Readme.md

@@ -0,0 +1,19 @@
+# ICGenealogy Channel: 101629\_naxn.mod
+
+## Details
+
+Name | Description
+---- | -----------
+ModelDB id | [101629](http://senselab.med.yale.edu/ModelDB/ShowModel.cshtml?model=101629)
+ICG id | [14](http://icg.neurotheory.ox.ac.uk/channels/2/14)
+ICG Class | [Na](http://icg.neurotheory.ox.ac.uk/channels/2)
+
+## Description
+
+This is a single channel model file that was originally part of a [published model on the ModelDB website](http://senselab.med.yale.edu/mModelDB/ShowModel.cshtml?model=101629).
+
+The file [101629\_naxn.mod](101629_naxn.mod) was extrated from [the ModelDB repository](http://senselab.med.yale.edu/ModelDB/ShowModel.cshtml?model=101629), and committed in its original form.
+
+## Usage
+
+See the [icg-channel super-repository](https://github.com/icgenealogy/icg-channels) for more information.

102288_Naaxon.mod/102288_Naaxon.mod

@@ -0,0 +1,116 @@
+COMMENT
+
+Sodium current for the soma
+
+References:
+
+1.	Martina, M., Vida, I., and Jonas, P.  Distal initiation and active
+	propagation of action potentials in interneuron dendrites,
+	Science, 287:295-300, 2000.
+
+			soma	axon-lacking dend	axon-bearing dend
+Na+	gmax	    107 ps/um2	   117 ps/um2		   107 ps/um2
+	slope 	    10.9 mV/e	   11.2 mV/e		   11.2 mV/e
+	V1/2        -37.8 mV       -45.6 mV                -45.6 mV
+
+
+
+2.	Marina, M. and Jonas, P.  Functional differences in Na+ channel
+	gating between fast-spiking interneurons and principal neurones of rat
+	hippocampus, J. Physiol., 505.3:593-603, 1997.
+
+*Note* The interneurons here are basket cells from the dentate gyrus.
+
+Na+	Activation V1/2				-25.1 mV
+	slope			 		11.5
+	Activation t (-20 mV)	 		0.16 ms
+	Deactivation t (-40 mV)	 		0.13 ms
+ 	Inactivation V1/2			-58.3 mV
+	slope			 		6.7
+	onset of inactivation t (-20 mV)	1.34 ms
+	onset of inactivation t (-55 mV)	18.6 ms
+	recovery from inactivation t		2.0 ms
+	(30 ms conditioning pulse)
+	recovery from inactivation t		2.7 ms
+	(300 ms conditioning pulse)
+
+ENDCOMMENT
+UNITS {
+        (mA) = (milliamp)
+        (mV) = (millivolt)
+}
+
+NEURON {
+        SUFFIX Naaxon
+        USEION na READ ena WRITE ina
+        RANGE gna, ina
+        GLOBAL minf, hinf, hexp, mtau, htau
+}
+
+INDEPENDENT {t FROM 0 TO 1 WITH 1 (ms)}
+
+PARAMETER {
+        v (mV)
+        celsius = 24 (degC)
+        dt (ms)
+        gna = .0107 (mho/cm2)
+        ena = 90 (mV)
+}
+
+STATE {
+        m h 
+}
+
+ASSIGNED {
+        ina (mA/cm2)
+        minf 
+	mexp 
+	hinf 
+	hexp
+	mtau (ms)
+	htau (ms)
+}
+
+INITIAL {
+	rate(v)
+	m = minf
+	h = hinf
+}
+
+BREAKPOINT {
+        SOLVE state METHOD cnexp
+	ina = gna*m*m*m*h*(v - ena)    
+}
+
+DERIVATIVE state {
+	rate(v)
+	m'=(minf-m)/mtau
+	h'=(hinf-h)/htau
+}
+
+UNITSOFF
+PROCEDURE rate(v(mV)) {  :Computes rate and other constants at 
+		      :current v.
+                      :Call once from HOC to initialize inf at resting v.
+        LOCAL q10, tinc, alpha, beta
+        TABLE minf, hinf, hexp, mtau, htau DEPEND celsius FROM -200 TO 100 WITH 300
+		q10 = 3^((celsius - 24)/10)
+		tinc = -dt*q10
+		alpha = 0.1*vtrap(-(v+38),10)
+		beta = 4*exp(-(v+63)/18)
+		mtau = 1/(alpha + beta)
+		minf = alpha*mtau
+		alpha = 0.07*exp(-(v+63)/20)
+		beta = 1/(1+exp(-(v+33)/10))
+		htau = 1/(alpha + beta)
+		hinf = alpha*htau
+		hexp = 1-exp(tinc/htau)
+}
+FUNCTION vtrap(x,y) {	:Traps for 0 in denominator of rate eqns.
+		if (fabs(x/y) < 1e-6) {
+			vtrap = y*(1 - x/y/2)
+		}else{
+			vtrap = x/(exp(x/y) - 1)
+		}
+}
+UNITSON