Warn for migration files that end in ".ex"

Closes 599.

lib/ecto/migrator.ex

@@ -662,6 +662,8 @@ defmodule Ecto.Migrator do
     migration_source
     |> Enum.flat_map(fn
       directory when is_binary(directory) ->
+        warn_for_misnamed_files(directory)
+
         Path.join([directory, "**", "*.exs"])
         |> Path.wildcard()
         |> Enum.map(&extract_migration_info/1)
@@ -673,6 +675,22 @@ defmodule Ecto.Migrator do
     |> Enum.sort()
   end
 
+  # See: https://github.com/elixir-ecto/ecto_sql/issues/599
+  defp warn_for_misnamed_files(directory) do
+    [directory, "**", "*.ex"]
+    |> Path.join()
+    |> Path.wildcard()
+    |> Enum.each(fn path ->
+      if Path.basename(path) =~ ~r/\d+_/ do
+        IO.warn("""
+        File #{Path.relative_to_cwd(path)} looks like a migration but ends in .ex. \
+        Migration files should end in .exs. Use "mix ecto.gen.migration" to generate \
+        migration files with the correct extension.\
+        """)
+      end
+    end)
+  end
+
   defp extract_migration_info(file) do
     base = Path.basename(file)
 

test/ecto/migrator_test.exs

@@ -3,6 +3,7 @@ defmodule Ecto.MigratorTest do
 
   import Support.FileHelpers
   import Ecto.Migrator
+  import ExUnit.CaptureIO
   import ExUnit.CaptureLog
 
   alias EctoSQL.TestRepo
@@ -405,6 +406,18 @@ defmodule Ecto.MigratorTest do
     end
   end
 
+  test "warns for .ex files that look like migrations" do
+    in_tmp(fn path ->
+      output =
+        capture_io(:stderr, fn ->
+          create_migration("123_looks_like_migration.ex")
+          assert run(TestRepo, path, :up, all: true, log: false) == []
+        end)
+
+      assert output =~ "File 123_looks_like_migration.ex looks like a migration"
+    end)
+  end
+
   describe "lock for migrations" do
     setup do
       put_test_adapter_config(test_process: self())