Check python version at compile

m4/ax_compare_version.m4

@@ -0,0 +1,177 @@
+# ===========================================================================
+#    https://www.gnu.org/software/autoconf-archive/ax_compare_version.html
+# ===========================================================================
+#
+# SYNOPSIS
+#
+#   AX_COMPARE_VERSION(VERSION_A, OP, VERSION_B, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
+#
+# DESCRIPTION
+#
+#   This macro compares two version strings. Due to the various number of
+#   minor-version numbers that can exist, and the fact that string
+#   comparisons are not compatible with numeric comparisons, this is not
+#   necessarily trivial to do in a autoconf script. This macro makes doing
+#   these comparisons easy.
+#
+#   The six basic comparisons are available, as well as checking equality
+#   limited to a certain number of minor-version levels.
+#
+#   The operator OP determines what type of comparison to do, and can be one
+#   of:
+#
+#    eq  - equal (test A == B)
+#    ne  - not equal (test A != B)
+#    le  - less than or equal (test A <= B)
+#    ge  - greater than or equal (test A >= B)
+#    lt  - less than (test A < B)
+#    gt  - greater than (test A > B)
+#
+#   Additionally, the eq and ne operator can have a number after it to limit
+#   the test to that number of minor versions.
+#
+#    eq0 - equal up to the length of the shorter version
+#    ne0 - not equal up to the length of the shorter version
+#    eqN - equal up to N sub-version levels
+#    neN - not equal up to N sub-version levels
+#
+#   When the condition is true, shell commands ACTION-IF-TRUE are run,
+#   otherwise shell commands ACTION-IF-FALSE are run. The environment
+#   variable 'ax_compare_version' is always set to either 'true' or 'false'
+#   as well.
+#
+#   Examples:
+#
+#     AX_COMPARE_VERSION([3.15.7],[lt],[3.15.8])
+#     AX_COMPARE_VERSION([3.15],[lt],[3.15.8])
+#
+#   would both be true.
+#
+#     AX_COMPARE_VERSION([3.15.7],[eq],[3.15.8])
+#     AX_COMPARE_VERSION([3.15],[gt],[3.15.8])
+#
+#   would both be false.
+#
+#     AX_COMPARE_VERSION([3.15.7],[eq2],[3.15.8])
+#
+#   would be true because it is only comparing two minor versions.
+#
+#     AX_COMPARE_VERSION([3.15.7],[eq0],[3.15])
+#
+#   would be true because it is only comparing the lesser number of minor
+#   versions of the two values.
+#
+#   Note: The characters that separate the version numbers do not matter. An
+#   empty string is the same as version 0. OP is evaluated by autoconf, not
+#   configure, so must be a string, not a variable.
+#
+#   The author would like to acknowledge Guido Draheim whose advice about
+#   the m4_case and m4_ifvaln functions make this macro only include the
+#   portions necessary to perform the specific comparison specified by the
+#   OP argument in the final configure script.
+#
+# LICENSE
+#
+#   Copyright (c) 2008 Tim Toolan <[email protected]>
+#
+#   Copying and distribution of this file, with or without modification, are
+#   permitted in any medium without royalty provided the copyright notice
+#   and this notice are preserved. This file is offered as-is, without any
+#   warranty.
+
+#serial 13
+
+dnl #########################################################################
+AC_DEFUN([AX_COMPARE_VERSION], [
+  AC_REQUIRE([AC_PROG_AWK])
+
+  # Used to indicate true or false condition
+  ax_compare_version=false
+
+  # Convert the two version strings to be compared into a format that
+  # allows a simple string comparison.  The end result is that a version
+  # string of the form 1.12.5-r617 will be converted to the form
+  # 0001001200050617.  In other words, each number is zero padded to four
+  # digits, and non digits are removed.
+  AS_VAR_PUSHDEF([A],[ax_compare_version_A])
+  A=`echo "$1" | sed -e 's/\([[0-9]]*\)/Z\1Z/g' \
+                     -e 's/Z\([[0-9]]\)Z/Z0\1Z/g' \
+                     -e 's/Z\([[0-9]][[0-9]]\)Z/Z0\1Z/g' \
+                     -e 's/Z\([[0-9]][[0-9]][[0-9]]\)Z/Z0\1Z/g' \
+                     -e 's/[[^0-9]]//g'`
+
+  AS_VAR_PUSHDEF([B],[ax_compare_version_B])
+  B=`echo "$3" | sed -e 's/\([[0-9]]*\)/Z\1Z/g' \
+                     -e 's/Z\([[0-9]]\)Z/Z0\1Z/g' \
+                     -e 's/Z\([[0-9]][[0-9]]\)Z/Z0\1Z/g' \
+                     -e 's/Z\([[0-9]][[0-9]][[0-9]]\)Z/Z0\1Z/g' \
+                     -e 's/[[^0-9]]//g'`
+
+  dnl # In the case of le, ge, lt, and gt, the strings are sorted as necessary
+  dnl # then the first line is used to determine if the condition is true.
+  dnl # The sed right after the echo is to remove any indented white space.
+  m4_case(m4_tolower($2),
+  [lt],[
+    ax_compare_version=`echo "x$A
+x$B" | sed 's/^ *//' | sort -r | sed "s/x${A}/false/;s/x${B}/true/;1q"`
+  ],
+  [gt],[
+    ax_compare_version=`echo "x$A
+x$B" | sed 's/^ *//' | sort | sed "s/x${A}/false/;s/x${B}/true/;1q"`
+  ],
+  [le],[
+    ax_compare_version=`echo "x$A
+x$B" | sed 's/^ *//' | sort | sed "s/x${A}/true/;s/x${B}/false/;1q"`
+  ],
+  [ge],[
+    ax_compare_version=`echo "x$A
+x$B" | sed 's/^ *//' | sort -r | sed "s/x${A}/true/;s/x${B}/false/;1q"`
+  ],[
+    dnl Split the operator from the subversion count if present.
+    m4_bmatch(m4_substr($2,2),
+    [0],[
+      # A count of zero means use the length of the shorter version.
+      # Determine the number of characters in A and B.
+      ax_compare_version_len_A=`echo "$A" | $AWK '{print(length)}'`
+      ax_compare_version_len_B=`echo "$B" | $AWK '{print(length)}'`
+
+      # Set A to no more than B's length and B to no more than A's length.
+      A=`echo "$A" | sed "s/\(.\{$ax_compare_version_len_B\}\).*/\1/"`
+      B=`echo "$B" | sed "s/\(.\{$ax_compare_version_len_A\}\).*/\1/"`
+    ],
+    [[0-9]+],[
+      # A count greater than zero means use only that many subversions
+      A=`echo "$A" | sed "s/\(\([[0-9]]\{4\}\)\{m4_substr($2,2)\}\).*/\1/"`
+      B=`echo "$B" | sed "s/\(\([[0-9]]\{4\}\)\{m4_substr($2,2)\}\).*/\1/"`
+    ],
+    [.+],[
+      AC_WARNING(
+        [invalid OP numeric parameter: $2])
+    ],[])
+
+    # Pad zeros at end of numbers to make same length.
+    ax_compare_version_tmp_A="$A`echo $B | sed 's/./0/g'`"
+    B="$B`echo $A | sed 's/./0/g'`"
+    A="$ax_compare_version_tmp_A"
+
+    # Check for equality or inequality as necessary.
+    m4_case(m4_tolower(m4_substr($2,0,2)),
+    [eq],[
+      test "x$A" = "x$B" && ax_compare_version=true
+    ],
+    [ne],[
+      test "x$A" != "x$B" && ax_compare_version=true
+    ],[
+      AC_WARNING([invalid OP parameter: $2])
+    ])
+  ])
+
+  AS_VAR_POPDEF([A])dnl
+  AS_VAR_POPDEF([B])dnl
+
+  dnl # Execute ACTION-IF-TRUE / ACTION-IF-FALSE.
+  if test "$ax_compare_version" = "true" ; then
+    m4_ifvaln([$4],[$4],[:])dnl
+    m4_ifvaln([$5],[else $5])dnl
+  fi
+]) dnl AX_COMPARE_VERSION

m4/python.m4

@@ -19,33 +19,17 @@ dnl
 
 dnl EGG_PYTHON_ENABLE
 dnl
-AC_DEFUN([EGG_PYTHON_ENABLE],
-[
-  AC_MSG_CHECKING([whether to compile the Python module])
-  AC_ARG_ENABLE(python,
-    [  --enable-python         enable Python support (autodetect)],
-    [egg_enable_python="$enableval"])
-  AC_ARG_ENABLE(python,
-    [  --disable-python        disable Python support], [egg_enable_python="$enableval"],
-    [egg_enable_python="autodetect"])
-
-  AC_MSG_RESULT([$egg_enable_python])
-  AC_SUBST(egg_enable_python)
-])
-
 
 dnl EGG_PYTHON_WITHCONFIG
 dnl
 AC_DEFUN(EGG_PYTHON_WITHCONFIG,
 [
   AC_ARG_WITH(python-config, [  --with-python-config=PATH      Path to python-config], [
-    if test "x$enable_python" != "xno"; then
-      if test -d "$withval" || test -x "$withval"; then
-        egg_with_python_config="$withval"
-      else
-        egg_with_python_config="no"
-        AC_MSG_WARN([Invalid path to python-config. $withval is not a directory and not an executable.])
-      fi
+    if test -d "$withval" || test -x "$withval"; then
+      egg_with_python_config="$withval"
+    else
+      egg_with_python_config="no"
+      AC_MSG_WARN([Invalid path to python-config. $withval is not a directory and not an executable.])
     fi
   ])
   AC_SUBST(egg_with_python_config)

src/mod/python.mod/configure.ac

@@ -4,8 +4,9 @@ AC_PREREQ(2.69)
 
 sinclude(../eggmod.m4)
 builtin(include,../../../m4/python.m4)
+builtin(include,../../../m4/ax_compare_version.m4)
 
-AC_INIT([Eggdrop Python Module],[1.9.3],[[email protected]])
+AC_INIT([Eggdrop Python Module],[1.10.0],[[email protected]])
 
 AC_CONFIG_SRCDIR(python.c)
 AC_CONFIG_AUX_DIR(../../../misc)
@@ -14,7 +15,6 @@ AC_COPYRIGHT([Copyright (C) 1999 - 2024 Eggheads Development Team])
 AC_REVISION([m4_esyscmd([../../../misc/getcommit])])
 
 AC_PROG_FGREP
-EGG_PYTHON_ENABLE
 EGG_PYTHON_WITHCONFIG
 
 python_avail="false"
@@ -60,19 +60,48 @@ if test "x$python_config_bin" != "x"; then
   python_avail="true"
 fi
 
+# Check python path
+AC_ARG_VAR([PYTHON_VERSION],[The installed Python
+version to use, for example '2.3'. This string
+will be appended to the Python interpreter
+canonical name.])
+
+AC_PATH_PROG([PYTHON],[python[$PYTHON_VERSION]])
+  if test -z "$PYTHON"; then
+    AC_MSG_WARN([Cannot find python$PYTHON_VERSION in your system path])
+    if ! $ax_python_devel_optional; then
+      AC_MSG_ERROR([Giving up, python development not available])
+    fi
+  ax_python_devel_found=no
+  PYTHON_VERSION=""
+fi
+
+# Check for python version
+  python_ver=`$PYTHON -c "import sys; \
+  print(sys.version.split ()[[0]])"`
+  AX_COMPARE_VERSION([$python_ver],[ge],[3.8.0], [ax_check_ver="yes"], [ax_check_ver="no"])
+  AC_MSG_CHECKING([$PYTHON version is >= 3.8.0])
+  if test "x$ax_check_ver" = x"no"; then
+    python_avail="false"
+    AC_MSG_RESULT([no ($python_ver)])
+    AC_MSG_WARN([Eggdrop requires python version 3.8.0 or higher])
+  else
+    AC_MSG_RESULT([yes ($python_ver)])
+  fi
+
 # Disable the module
 if test "x$python_avail" = "xfalse"; then
   if test "x$egg_enable_python" != "xno"; then
     cat >&2 <<EOF
-configure: warning:
 
-  Your system does not provide a working python-config binary.
-  The python module will therefore be disabled.
+  There was an issue with your python installation.
+  Please read python.mod/config.log for more details.
+  The python module will be disabled.
 
 EOF
   fi
   EGG_REMOVE_MOD(python)
 fi
 
 AC_CONFIG_FILES([Makefile])
-AC_OUTPUT
+AC_OUTPUT