feat: nix build

.gitignore

@@ -1,5 +1,6 @@
 dist/
 node_modules/
+result
 storybook-static/
 themes/
 .eslintcache

.yarnrc.yml

@@ -5,5 +5,7 @@ plugins:
     spec: "@yarnpkg/plugin-interactive-tools"
   - path: .yarn/plugins/plugin-list.cjs
     spec: "https://github.com/arendjr/yarn-plugin-list/releases/latest/download/yarn-plugin-list.js"
+  - path: .yarn/plugins/yarn-plugin-nixify.cjs
+    spec: "https://raw.githubusercontent.com/stephank/yarn-plugin-nixify/main/dist/yarn-plugin-nixify.js"
 
-yarnPath: .yarn/releases/yarn-3.6.3.cjs
+yarnPath: .yarn/releases/yarn-3.6.3.cjs

README.md

@@ -63,6 +63,50 @@ You can find the compiled theme JSON files (with default settings as documented
 
 This can be useful if you want to use syntax highlighters that work with VSCode themes (like Shiki and derivatives), or if your work environment only allows you to install allowlisted extensions.
 
+**Nix (Home-Manager) users**
+
+If you want to change the theme configuration, the theme expects to have a mutable directory to write it's JSON files into.
+This means that you will have to either
+
+- Install this extension in a non-declarative way, so that the extension has permissions to write files.\
+  This means fully excluding `nixpkgs.vscode-extensions.catppuccin.catppuccin-vsc` from your configuration; Just using `programs.vscode.mutableExtensionsDir = true;` will **NOT WORK**.
+- Use the `flake.nix` to build it with your VSCode configuration, using overrides.\
+  This is a declarative way to compile the theme with your preferred options. Please see the example below for a sample configuration.
+
+<details>
+<summary>❄️ Nix Configuration</summary>
+
+```nix
+{
+  # in your inputs:
+  inputs.catppuccin-vsc.url = "github.com:catppuccin/vscode";
+
+  # add the overlay:
+  nixpkgs.overlays = [inputs.catppuccin-vsc.overlays.default];
+  # the package will be available as
+  # - pkgs.catppuccin-vsc
+  # - pkgs.vscode-extensions.catppuccin.catppuccin-vsc
+
+  # in your home-manager options:
+  programs.vscode.extensions = [
+    # all the theme options will be available as overrides, these are defaults:
+    (pkgs.catppuccin-vsc.override {
+      accentColor = "mauve";
+      boldKeywords = true;
+      italicComments = true;
+      italicKeywords = true;
+      extraBordersEnabled = false;
+      workbenchMode = "default";
+      bracketMode = "rainbow";
+      colorOverrides = {};
+      customUIColors = {};
+    })
+  ];
+}
+```
+
+</details>
+
 ## Customization
 
 > **Note**\

default.nix

@@ -0,0 +1,57 @@
+{
+  pkgs ? import <nixpkgs> {},
+  accentColor ? "mauve",
+  boldKeywords ? true,
+  italicComments ? true,
+  italicKeywords ? true,
+  extraBordersEnabled ? false,
+  workbenchMode ? "default",
+  bracketMode ? "rainbow",
+  colorOverrides ? {},
+  customUIColors ? {},
+} @ inputs: let
+  inherit (pkgs) lib;
+
+  packageJSON = builtins.fromJSON (builtins.readFile ./package.json);
+  properties = (builtins.head packageJSON.contributes.configuration).properties;
+  validAccents = properties."catppuccin.accentColor".enum;
+  validWorkbenchModes = properties."catppuccin.workbenchMode".enum;
+  validBracketModes = properties."catppuccin.bracketMode".enum;
+
+  inherit (packageJSON) name version;
+  pname = "${name}-${version}";
+
+  options = builtins.removeAttrs inputs ["pkgs"];
+  project =
+    (pkgs.callPackage ./yarn-project.nix {} {
+      src = pkgs.nix-gitignore.gitignoreSource [] ./.;
+    })
+    .overrideAttrs (old: {
+      # check in the ./themes/.flag so it doesn't prompt for initial rebuilds
+      patchPhase = ''
+        printf "\n!themes/.flag\n" >> .vscodeignore
+      '';
+      buildPhase = ''
+        yarn compile
+        yarn compile:theme '${builtins.toJSON options}'
+        touch ./themes/.flag
+        yarn package
+      '';
+      installPhase = ''
+        mkdir -p $out
+        # rename the file extension to zip for the buildVSCodeMarketplaceExtension builder
+        mv catppuccin-vsc-*.vsix $out/catppuccin-vsc.zip
+      '';
+    });
+in
+  (lib.checkListOfEnum "${pname}: accent" validAccents [accentColor])
+  (lib.checkListOfEnum "${pname}: workbenchMode" validWorkbenchModes [workbenchMode])
+  (lib.checkListOfEnum "${pname}: bracketMode" validBracketModes [bracketMode])
+  pkgs.vscode-utils.buildVscodeMarketplaceExtension {
+    vsix = "${project.outPath}/catppuccin-vsc.zip";
+    mktplcRef = {
+      # lowercase since it is used in the pname
+      publisher = "catppuccin";
+      inherit name version;
+    };
+  }

flake.nix

@@ -0,0 +1,38 @@
+{
+  inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
+
+  outputs = {nixpkgs, ...} @ inputs: let
+    systems = ["aarch64-darwin" "aarch64-linux" "x86_64-darwin" "x86_64-linux"];
+    forAllSystems = f: nixpkgs.lib.genAttrs systems (system: f system);
+  in {
+    packages = forAllSystems (system: let
+      pkgs = nixpkgs.legacyPackages.${system};
+    in rec {
+      default = catppuccin-vsc;
+      catppuccin-vsc = pkgs.callPackage ./. {};
+    });
+
+    overlays.default = final: prev: let
+      pkg = inputs.self.packages.${prev.stdenv.hostPlatform.system}.default;
+    in {
+      # create a new package
+      catppuccin-vsc = pkg;
+      # overwrite the vscode-extensions package
+      vscode-extensions =
+        prev.vscode-extensions
+        // {
+          catppuccin =
+            (prev.vscode-extensions.catppuccin or {})
+            // {
+              catppuccin-vsc = pkg;
+            };
+        };
+    };
+
+    devShells = forAllSystems (system: let
+      pkgs = nixpkgs.legacyPackages.${system};
+    in {
+      default = import ./shell.nix {inherit pkgs;};
+    });
+  };
+}

src/hooks/generateThemes.ts

@@ -8,8 +8,11 @@ import type { CatppuccinFlavour } from "../types";
 const themeDir = path.join(__dirname, "../../themes");
 const flavours = Object.keys(variants) as CatppuccinFlavour[];
 
+// options can also be passed as a JSON string
+const options = process.argv[2] ? JSON.parse(process.argv[2]) : {};
+
 flavours.map((flavour) => {
-  const theme = compileTheme(flavour, defaultOptions);
+  const theme = compileTheme(flavour, { ...defaultOptions, ...options });
   // ignore error if directory exists
   fs.mkdir(themeDir, { recursive: true }).then(() => {
     fs.writeFile(