feat(home-manager): add support for kvantum

modules/home-manager/kvantum.nix

@@ -0,0 +1,46 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+let
+  cfg = config.qt.style.catppuccin;
+  enable =
+    cfg.enable
+    && config.qt.enable
+    && lib.elem config.qt.style.name [
+      "kvantum"
+      "Kvantum"
+    ];
+  flavourCapitalized = lib.ctp.mkUpper cfg.flavour;
+  accentCapitalized = lib.ctp.mkUpper cfg.accent;
+  theme = pkgs.catppuccin-kvantum.override {
+    accent = accentCapitalized;
+    variant = flavourCapitalized;
+  };
+in
+{
+  options.qt.style.catppuccin = lib.ctp.mkCatppuccinOpt "Kvantum" // {
+    accent = lib.ctp.mkAccentOpt "Kvantum";
+
+    apply = lib.mkOption {
+      type = lib.types.bool;
+      default = true;
+      description = ''
+        Applies the theme by overwriting `$XDG_CONFIG_HOME/Kvantum/kvantum.kvconfig`.
+        If this is disabled, you must manually set the theme (e.g. by using `kvantummanager`).
+      '';
+    };
+  };
+
+  config.xdg.configFile = lib.mkIf enable {
+    "Kvantum/Catppuccin-${flavourCapitalized}-${accentCapitalized}".source = "${theme}/share/Kvantum/Catppuccin-${flavourCapitalized}-${accentCapitalized}";
+    "Kvantum/kvantum.kvconfig" = lib.mkIf cfg.apply {
+      text = ''
+        [General]
+        theme=Catppuccin-${flavourCapitalized}-${accentCapitalized}
+      '';
+    };
+  };
+}

test.nix

@@ -121,6 +121,10 @@ testers.runNixOSTest {
 
         gtk = lib.recursiveUpdate enable { catppuccin.cursor.enable = true; };
 
+        qt = enable // {
+          style.name = "kvantum";
+        };
+
         services = {
           dunst = enable;
           mako = enable;