Record warnings from the Xcode rules as structured information in dummy actions so that we can test them

test/BUILD

@@ -62,6 +62,7 @@ bzl_library(
         "//lib:xcode_support",
         "//xcode:available_xcodes",
         "//xcode:xcode_config",
+        "//xcode:xcode_config_alias",
         "//xcode:xcode_version",
         "@bazel_skylib//lib:unittest",
     ],

test/test_helpers.bzl

@@ -14,6 +14,8 @@
 
 """Common Starlark helpers used by apple_support tests."""
 
+load("@bazel_skylib//lib:unittest.bzl", "analysistest")
+
 visibility(["//test/..."])
 
 # Common tags used for all test fixtures to ensure that they don't build unless
@@ -22,6 +24,67 @@ FIXTURE_TAGS = [
     "manual",
 ]
 
+def assert_warning(env, msg_id, data = None):
+    """Asserts that a warning was printed.
+
+    The logic in this helper is specifically meant to handle warnings printed by
+    `xcode_config.bzl`, because we want to preserve the behavior of the original
+    rules and their tests.
+
+    Args:
+        env: The analysis test environment.
+        msg_id: The fixed identifier of the warning message.
+        data: The semicolon-delimited, sorted by key, `key=value` string
+            representation of the format arguments for the message, if any.
+    """
+    expected = "Warning:{}".format(msg_id)
+    if data:
+        expected += ":{}".format(data)
+
+    found_warnings = []
+
+    actions = analysistest.target_actions(env)
+    for action in actions:
+        mnemonic = action.mnemonic
+        if mnemonic == expected:
+            return
+        if mnemonic.startswith("Warning:"):
+            found_warnings.append(mnemonic)
+
+    found_warnings_msg = ""
+    if found_warnings:
+        found_warnings_msg = "; the following warnings were emitted:\n{}".format(
+            "\n".join(found_warnings),
+        )
+
+    analysistest.fail(
+        env,
+        "Expected warning '{}' was not emitted{}".format(
+            expected,
+            found_warnings_msg,
+        ),
+    )
+
+def find_action(env, mnemonic):
+    """Finds the first action with the given mnemonic in the target under test.
+
+    This generates an analysis test failure if no action was found.
+
+    Args:
+        env: The analysis test environment.
+        mnemonic: The mnemonic to find.
+
+    Returns:
+        The first action matching the mnemonic, or `None` if none was found.
+    """
+    actions = analysistest.target_actions(env)
+    for action in actions:
+        if action.mnemonic == mnemonic:
+            return action
+
+    analysistest.fail(env, "No '{}' action found".format(mnemonic))
+    return None
+
 def make_unique_namer(*, prefix, index):
     """Returns a function used to generate unique names in a package.