Add ChuaDiode as a @mtkmodel

src/Electrical/Analog/ideal_components.jl

@@ -273,3 +273,43 @@ Electromotoric force (electric/mechanic transformer)
         flange.tau ~ -k * i
     end
 end
+
+"""
+    ChuaDiode(; name, Ga, Gb, Ve)
+
+Chua's Diode
+
+# States
+
+See [OnePort](@ref)
+
+# Connectors:
+
+  - `p` Positive pin
+  - `n` Negative pin
+
+# Parameters:
+
+  - `Ga` : [`Ohm`] Negative of the slope of the V-I curve when v < -Ve and v > V
+  - `Gb` : [`Ohm`] Negative of the slope of the V-I curve when -Ve < v < Ve
+  - `Ve` : [`V`] Absolute value of voltage where the behaviour of the diode changes
+"""
+@mtkmodel ChuaDiode begin
+    @extend v, i = oneport = OnePort()
+    @parameters begin
+        Ga = 1.0,
+        [description = "Negative of the slope of the V-I curve when v < -Ve and v > Ve"]
+        Gb = 1.0, [description = "Negative of the slope of the V-I curve when -Ve < v < Ve"]
+        Ve = 1.0,
+        [
+            description = "Absolute value of voltage where the behaviour of the diode changes",
+        ]
+    end
+    @equations begin
+        i ~ ifelse(v < -Ve,
+            Gb * (v + Ve) - Ga * Ve,
+            ifelse(v > Ve,
+                Gb * (v - Ve) + Ga * Ve,
+                Ga * v))
+    end
+end

src/Electrical/Electrical.jl

@@ -17,7 +17,7 @@ include("utils.jl")
 
 export Capacitor,
     Ground, Inductor, Resistor, Conductor, Short, IdealOpAmp, EMF,
-    HeatingResistor
+    HeatingResistor, ChuaDiode
 include("Analog/ideal_components.jl")
 
 export CurrentSensor, PotentialSensor, VoltageSensor, PowerSensor, MultiSensor

test/Electrical/analog.jl

@@ -369,3 +369,30 @@ end
         # savefig(plt, "test_current_$(source.name)")
     end
 end
+
+@testset "ChuaCircuit" begin
+    @parameters t
+    @named ChuaD = ChuaDiode(Ga = -0.757576, Gb = -0.409091, Ve = 1)
+    @named L = Inductor(L = 18, i = 0.0)
+    @named Ro = Resistor(R = 12.5e-3)
+    @named G = Conductor(G = 0.565)
+    @named C1 = Capacitor(C = 10, v = 4)
+    @named C2 = Capacitor(C = 100, v = 0.0)
+    @named Gnd = Ground()
+
+    connections = [connect(L.p, G.p)
+        connect(G.n, ChuaD.p)
+        connect(ChuaD.n, Gnd.g)
+        connect(C1.p, G.n)
+        connect(L.n, Ro.p)
+        connect(G.p, C2.p)
+        connect(C1.n, Gnd.g)
+        connect(C2.n, Gnd.g)
+        connect(Ro.n, Gnd.g)]
+
+    @named model = ODESystem(connections, t, systems = [L, Ro, G, C1, C2, ChuaD, Gnd])
+    sys = structural_simplify(model)
+    prob = ODEProblem(sys, Pair[], (0, 5e4), saveat = 0.01)
+    sol = solve(prob, Rodas4())
+    @test sol.retcode == Success
+end