build.gradle

/*
 * Copyright 2012 the original author or authors.
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

apply plugin: 'java'

defaultTasks = ['assemble']

sourceCompatibility = '1.7'
targetCompatibility = '1.7'

jar.enabled = false // we don't need this

compileJava.options.compilerArgs << "-Xlint:unchecked" << "-Werror"

repositories {
  maven { url 'https://oss.sonatype.org/content/repositories/snapshots' }
  mavenCentral()
}

configurations {
  provided
}

dependencies {
  compile "c3p0:c3p0:$c3p0Version"
  compile "commons-dbutils:commons-dbutils:$dbutilsVersion"
  provided     "org.vert-x:vertx-core:$vertxVersion"
  provided     "org.vert-x:vertx-platform:$vertxVersion"

  testCompile "org.vert-x:vertx-core:$vertxVersion"
  testCompile "org.vert-x:vertx-platform:$vertxVersion"
  testCompile "org.vert-x:vertx-lang-java:$vertxVersion"
  testCompile "org.vert-x:vertx-lang-rhino:$vertxVersion"
  testCompile "org.mozilla:rhino:$rhinoVersion"
  testCompile "org.hsqldb:hsqldb:$hsqldbVersion"

  testCompile( "org.vert-x:vertx-testframework:$vertxVersion" ) {
    transitive = false // don't need all of the other language deps
  }
  testCompile "junit:junit:$junitVersion"
}

sourceSets {
  main {
    compileClasspath = compileClasspath + configurations.provided
  }
}

task prepareVertxModule( type:Copy, dependsOn: 'classes' ) {
  into "build/mod/$modulename-v$version"
  from 'build/classes/main'
  from 'src/main/conf'
  into( 'lib' ) {
    from configurations.compile
  }
}

// Package into build/libs/mod.zip
task distZip( type: Zip, dependsOn: 'prepareVertxModule' ) {
  group = 'vert.x'
  description = "Assembles a vert.x module in 'mod.zip' format"
  destinationDir = project.file('build/libs')
  archiveName = 'mod.zip'
  from( project.file( "build/mod/${modulename}-v${version}" ) ).into( "${modulename}-v${version}" )
}

// Check build/libs/mod.zip has a single root, and a mod.json entry
task dist( dependsOn: 'distZip' ) << {
  def entries = new java.util.zip.ZipFile( project.file( 'build/libs/mod.zip' ) ).entries().collect { it.name }
  def oneRoot = entries.every { it.startsWith "${modulename}-v${version}/" }
  def modjson = entries.find { it == "${modulename}-v${version}/mod.json" }
  if( !oneRoot ) {
    throw new GradleException( "Invalid mod.zip.  Multiple root folders located!" )
  }
  else if( !modjson ) {
    throw new GradleException( "Invalid mod.zip.  Cannot locate ${modulename}-v${version}/mod.json" )
  }
}

task prepareVertxTest(type: Sync, dependsOn: ['prepareVertxModule']) {
  from 'build/mod'
  into 'build/tmp/mod-test'
}

test {
  // Can't have the app on the vert.x classpath
  classpath = files( classpath.findAll {
    !( it.toString() ==~ /.+build\/(classes|resources)\/main$/ )
  } )

  // Some vert.x properties
  systemProperty 'vertx.test.timeout', 15
  systemProperty 'vertx.mods', "$projectDir/build/tmp/mod-test"
  systemProperty 'vertx.version', "$project.version"

  // Show output
  testLogging.showStandardStreams = true

  // No idea why we need to depend on testClasses...
  dependsOn << [ 'testClasses', 'prepareVertxTest' ]
}

task collectDeps(type: Copy) {
  group = 'vert.x'
  description = 'conveniently collect dependencies for other IDEs'
  destinationDir = file("build/deps")
  into("compile") {
    from configurations.compile
  }
  into("test") {
    from configurations.testCompile
  }
}

task wrapper(type: Wrapper) {
    gradleVersion = '1.1'
    jarFile = 'gradle/wrapper.jar'
}