OVERNIGHT SCHEDULING

[glenbuck1]

Using Liquidsoap 2.2.5, I want to be able to schedule a three-hour show named MemoryLane starting at 23:00 and ending at 02:00. At present, when I do this, the audio stops at midnight although the title streaming still appears to be live. Is there a way to do this, please?

My script file contains the following:

MemoryLane=mksafe(normalize(playlist(mode="normal", "/home/radio/playlists/MemoryLane.pls")))

Monday=mksafe(switch(track_sensitive=false, [({0h-15h}, SixtiesPlus), ({15h-23h}, SixtiesPlus), ({23h-2h}, MemoryLane)]))
Tuesday=mksafe(switch(track_sensitive=false, [({2h-13h}, SixtiesPlus), ({13h-14h}, Country), ({14h-16h}, KickinCountry), ({16h-0h}, SixtiesPlus)]))

radio=mksafe(switch(track_sensitive=false, [({1w}, Monday), ({2w}, Tuesday), ({3w}, Wednesday), ({4w}, Thursday), ({5w}, Friday), ({6w}, Saturday), ({7w}, Sunday)]))

Any help greatly appreciated.

Thanks
Richard Bartholomew

[vitoyucepi]

Hi @glenbuck1,

You might want to integrate all the switches together.

radio = switch([
  ({1w0h-1w15h}, SixtiesPlus),
  ({1w15h-1w23h}, SixtiesPlus),
  ({1w23h-2w2h}, MemoryLane),
  ({2w2h-2w13h}, SixtiesPlus),
  ({2w13h-2w14h}, Country),
  ({2w14h-2w16h}, KickinCountry),
  ({2w16h-2w24h}, SixtiesPlus),
])

Monday=switch(
  [
    ({1w0h-1w15h}, SixtiesPlus),
    ({1w15h-1w23h}, SixtiesPlus),
    ({1w23h-2w2h}, MemoryLane)
  ],
  track_sensitive=false
)
Tuesday=switch(
  [
    ({2h-13h}, SixtiesPlus),
    ({13h-14h}, Country),
    ({14h-16h}, KickinCountry),
    ({16h-0h}, SixtiesPlus)
  ],
  track_sensitive=false
)

radio=mksafe(switch(
  [
    ({true}, Monday),
    ({2w}, Tuesday),
    ({3w}, Wednesday),
    ({4w}, Thursday),
    ({5w}, Friday),
    ({6w}, Saturday),
    ({7w}, Sunday)
  ],
  track_sensitive=false
))

Also, why don't you use switch(track_sensitive=true)?

[glenbuck1]

Thanks very much for your helpful reply and I'll try that today/tonight.

As far as why I'm not using switch(track_sensitive=true), I must admit that I can't remember!!! This particular bit of the script was set up a while ago and I'll need to read up again about the pros and cons of true vs false as I can't remember the reasoning behind it by the person who originally set it up.

Thanks again for your help.

[glenbuck1]

Hi,

As I was short of time yesterday to implement your whole suggestion, I just made the following changes to the script:

Tuesday=mksafe(switch(track_sensitive=false, [({2w2h-2w13h}, SixtiesPlus), ({2w13h-2w14h}, Country), ({2w14h-2w15h}, SixtiesPlus), ({2w15h-2w17h}, StandardTime), ({2w17h-2w23h}, SixtiesPlus), ({2w23h-3w2h}, MemoryLane)]))
Wednesday=mksafe(switch(track_sensitive=false, [({3w2h-3w15h}, SixtiesPlus), ({3w15h-3w17h}, StandardTime), ({3w17h-3w19h}, Seventies), ({3w19h-3w20h}, Jazz), ({3w20h-3w22h}, Sixties), ({3w22h-4w0h}, SixtiesPlus)]))

Unfortunately, this still stopped playing the audio at midnight so I shall try your full suggestion today without, I admit, fully understanding why it should work over what I did.

You asked why I was using track_sensitive=false rather than true...this is because we don't want the previous track to complete when switching to a new stream.

Thanks again for suggestion.

[vitoyucepi]

How do you combine days of week together?

[glenbuck1]

If I understand you correctly, I combine days as follows:

Tuesday=mksafe(switch(track_sensitive=false, [({2w2h-2w13h}, SixtiesPlus), ({2w13h-2w14h}, Country), ({2w14h-2w15h}, SixtiesPlus), ({2w15h-2w17h}, StandardTime), ({2w17h-2w23h}, SixtiesPlus), ({2w23h-3w2h}, MemoryLane)]))
Wednesday=mksafe(switch(track_sensitive=false, [({3w2h-3w15h}, SixtiesPlus), ({3w15h-3w17h}, StandardTime), ({3w17h-3w19h}, Seventies), ({3w19h-3w20h}, Jazz), ({3w20h-3w22h}, Sixties), ({3w22h-4w0h}, SixtiesPlus)]))

Look at the final entry for Tuesday and the first for Wednesday. The show plays correctly up until midnight but, after that, there's just silence until 2 AM when the next stream starts playing.

Hope this is what you were asking for.

[vitoyucepi]

I apologize for asking a vague question; it was not specific enough.
Let me show an example

Monday=switch(
  [
    ({1w0h-1w15h}, SixtiesPlus),
    ({1w15h-1w23h}, SixtiesPlus),
    ({1w23h-2w2h}, MemoryLane)
  ],
  track_sensitive=false
)
Tuesday=switch(
  [
    ({2w2h-2w13h}, SixtiesPlus),
    ({2w13h-2w14h}, Country),
    ({2w14h-2w15h}, SixtiesPlus),
    ({2w15h-2w17h}, StandardTime),
    ({2w17h-2w23h}, SixtiesPlus),
    ({2w23h-3w2h}, MemoryLane)
  ],
  track_sensitive=false
)
radio=mksafe(switch(
  [
    ({1w}, Monday),
    ({2w}, Tuesday),
  ],
  track_sensitive=false
))

The last switch will use Tuesday from 0:00 to 24:00; however, it will not produce anything from 0:00 to 2:00.

[glenbuck1]

Hi,

Yes, that's exactly what I'm experiencing. Is there a way to get the show to continue from midnight to 2 AM, please?

Thanks

[vitoyucepi]

You may want to use

Single switch

radio = switch([
  ({1w0h-1w15h}, SixtiesPlus),
  ({1w15h-1w23h}, SixtiesPlus),
  ({1w23h-2w2h}, MemoryLane),
  ({2w2h-2w13h}, SixtiesPlus),
  ({2w13h-2w14h}, Country),
  ({2w14h-2w16h}, KickinCountry),
  ({2w16h-2w24h}, SixtiesPlus),
])

Always true

radio=mksafe(switch(
  [
    ({true}, Monday),
    ({2w}, Tuesday),
    ({3w}, Wednesday),
    ({4w}, Thursday),
    ({5w}, Friday),
    ({6w}, Saturday),
    ({7w}, Sunday)
  ],
  track_sensitive=false
))

More days

radio=mksafe(switch(
  [
    ({0w-2w}, Monday),
    ({1w-3w}, Tuesday),
    ({3w}, Wednesday),
    ({4w}, Thursday),
    ({5w}, Friday),
    ({6w}, Saturday),
    ({7w}, Sunday)
  ],
  track_sensitive=false
))

Fallback

radio=mksafe(fallback(
  [
    Monday,
    Tuesday,
    Wednesday,
    Thursday,
    Friday,
    Saturday,
    Sunday
  ],
  track_sensitive=false
))