Get json specified metadata

[gAlleb]

Hi! So I've been experimenting with harbor and stuff. After a bunch of iterations I couldn't come up with a simple feature :(

All I want is to send only metadata which I specify. For example: only "artist" and "title".

I can use this:

meta = ref([])

s.on_metadata(fun (m) -> meta := m)

def get_meta(_, response) =
  response.json(meta())
end

harbor.http.register(port=7000, method="GET", "/getmeta", get_meta)

But it gives me a massive amount of info. How can I reduce this array to the data I need? Or even better: how to determine it by hand?

[toots]

I think that you need to specify which metadata you want exported. We provide metadata.export which is based on https://www.liquidsoap.info/doc-2.2.4/settings.html#exported-metadata. Otherwise, you can code your own filter.

[gAlleb]

Well, it seems handy but unclear for me)
Supposedly I add settings.encoder.metadata.export.set(["artist","title","album","song"]). But whats next? It doesn't do a thing.
I would much prefer to code my own filter but I can't. Just want to request specific metadata on_track, make a json out of it and register it on harbor. I've tried a bunch of functions but there is always an error. Something I'm missing or simply don't understand.

[vitoyucepi]

Hi @gAlleb,

You can use source.last_metadata() ?? [] to get the last known metadata for source.
Compared to previous question you have to use json() because metadata has unknown keys. If you want to use a known set of keys, then record would be fine.
Also, you should use base64 if you want to send an image.

[gAlleb]

Thanks so much, Vito!

 log.severe(error.message, label=http)

Error 5: this value has type
  unit
but it should be a subtype of the type of the value at log.liq, line 9, char 16-21
  string (inferred at log.liq, line 9, char 22-28)

probably we should use "http"

And what if I want to combine artist & title like I've used before song = "#{m[\"artist\"]} - #{m[\"title\"]}"?

[vitoyucepi]

I would prefer to combine it on client side.

[gAlleb]

Ha! Knew that you'd say that :)

Thank you)

[vitoyucepi]

You will process them anyways. Elapsed and duration are not formatted and may be null, artist and title may be null.

default_stream_title = "Default" # null()

stream_title =
  if title == null() then
    default_stream_title
  elsif artist = null() then
    title
  else
    "#{artist} - #{title}"
  end

[gAlleb]

Thanks a lot!

[gAlleb]

Hi, @vitoyucepi!

Been trying out how are things with 2.3.0. Could you help, please?

This is the function which works flawlessly in 2.2.5:

def write_json_nowplaying(omfm_0)

  def write_data()

  def null_float(f)
    f == infinity ? null() : f
  end

  def null_list(key, _list)
    list.assoc.mem(key, _list) ? list.assoc(key, _list) : null()
  end

  m = omfm_0.last_metadata() ?? []
 
  file_duration = null.get(default=0.0, request.duration(m["filename"]))

  pre_artist = null_list("artist", m)
  
  pre_title = null_list("title", m)
  
  default_stream_title = "Default" # null()
  stream_title =
  if pre_title == null() then
    default_stream_title
  elsif pre_artist == null() then
    pre_title
  else
    "#{pre_artist} - #{pre_title}"
  end

  artist = ref("")
  title = ref("")


     if pre_artist == null() then
        if string.contains(substring=" - ", m["title"]) then
            let (a, t) = string.split.first(separator=" - ", m["title"])
       	    title := t
            artist := a
        end
     else
            title := pre_title
            artist := pre_artist
     end


  np = {

    station = {
      name = "omFM",
      shortcode = "radio",
      timezone = "Europe/Moscow"

    },
    now_playing = {
      played_at = null_list("on_air_timestamp", m),
      played_at_timestamp = null_list("on_air_timestamp", m),
      played_at_date_time = null_list("on_air", m),
      duration = null_float(source.duration(omfm_0)),
      elapsed = null_float(source.elapsed(omfm_0)),
      remaining = null_float(source.remaining(omfm_0)),
      playlist = null_list("playlist", m),
      filename = null_list("filename", m),

      song = { 
           	text = stream_title,
     	  	artist = artist(),
         	title = title(),
          	album = null_list("album", m),
 	 	genre = null_list("genre", m),
        	song_duration = null_float(file_duration)
	     }

      

      #playlist = source.id(omfm_0),
     
       },

    song_history = songHistory()
  
  }

if (m["jingle_mode"] != "true") then
send_mq_event(json.stringify(np, compact=true))
end

 end

  thread.run(write_data, every=1.0, fast=false)
end
write_json_nowplaying(omfm_0)

But gives an error in 2.3.0

At /home/radio/liquidsoap/omfm/omfm.liq, line 536, char 22-28:
write_json_nowplaying(omfm_0)

Error 5: this value has type
  _.{last_metadata : (...) -> _?} (inferred at /home/radio/liquidsoap/omfm/omfm.liq, line 103 char 9 - line 107 char 2)
but it should be a subtype of
  _.{last_metadata? : (...) -> [_]}

I've tried lots of things: editing/deleting some of the lines. With every iteration new inconsistency appears.

In 2.2.5 - this works fine.

Same goes for another function with harbour:

def get_metadata(_)

  def null_float(f)
    f == infinity ? null() : f
  end

  def null_list(key, _list)
    list.assoc.mem(key, _list) ? list.assoc(key, _list) : null()
  end

  #log("method: #{request.method}")

  m = omfm_0.last_metadata() ?? []

  file_duration = null.get(default=0.0, request.duration(m["filename"]))

  pre_artist = null_list("artist", m)
  
  pre_title = null_list("title", m)
  
  default_stream_title = "Default" # null()
  stream_title =
  if pre_title == null() then
    default_stream_title
  elsif pre_artist == null() then
    pre_title
  else
    "#{pre_artist} - #{pre_title}"
  end

  artist = ref("")
  title = ref("")


     if pre_artist == null() then
        if string.contains(substring=" - ", m["title"]) then
            let (a, t) = string.split.first(separator=" - ", m["title"])
       	    title := t
            artist := a
        end
     else
            title := pre_title
            artist := pre_artist
     end

  data = {

    station = {
      name = "omFM",
      shortcode = "radio",
      timezone = "Europe/Moscow"

    },
    now_playing = {
      played_at = null_list("on_air_timestamp", m),
      played_at_timestamp = null_list("on_air_timestamp", m),
      played_at_date_time = null_list("on_air", m),
      duration = null_float(source.duration(omfm_0)),
      elapsed = null_float(source.elapsed(omfm_0)),
      remaining = null_float(source.remaining(omfm_0)),
      playlist = null_list("playlist", m),
      filename = null_list("filename", m),

      song = { 
           	text = stream_title,
     	  	artist = artist(),
         	title = title(),
          	album = null_list("album", m),
 	 	genre = null_list("genre", m),
        	song_duration = null_float(file_duration)
	     }

      

      #playlist = source.id(omfm_0),
     
     },

    song_history = songHistory()
  
  }
 try

  http.response(
    status_code=200,
    headers=[
                ("Content-Type", "application/json"),
                ("Access-Control-Allow-Origin","*")
            ],
    content_type="application/json; charset=UTF-8",
    data=json.stringify(data, compact=true) ^ "\n"
  )

 catch error do

  log.severe(error.message, label="http")
  http.response(
    status_code=500,
    content_type="application/json; charset=UTF-8",
    data='{"status":"error","message":"Failed to serialize response data"}' ^ "\n"
  )

  end
end

harbor.http.register.simple("/nowplaying", get_metadata, port=8007, method="GET")

It gives me:

At /home/radio/liquidsoap/omfm/omfm.liq, line 527, char 57-59:
  file_duration = null.get(default=0.0, request.duration(m["filename"]))

Error 5: this value has type
  _? (inferred at /home/radio/liquidsoap/omfm/omfm.liq, line 525, char 6-34)
but it should be a subtype of
  [_]

Ok, if I get rid of file_duration = null.get(default=0.0, request.duration(m["filename"])) it gives me next error:

At /home/radio/liquidsoap/omfm/omfm.liq, line 529, char 35:
  pre_artist = null_list("artist", m)

Error 5: this value has type
  _? (inferred at /home/radio/liquidsoap/omfm/omfm.liq, line 525, char 6-34)
but it should be a subtype of
  [_]

And so on and so on :) As you see almost every error is connected with something being _? when it needs to be [_]. inferred at points sometimes to random lines and to m = omfm_0.last_metadata() ?? [].

---

However I've got a telegram function which continues to work fine in 2.3.0. Probably because it gets m from on_metadata and not last_metadata() as far as my newb mind sees it :

def telegram_omFM(m)

  def handle_error(error)
    log.important(
      "Unable to send Telegram event. #{error.message}",
      label="Telegram"
    )
  end

  def null_list(key, _list)
    list.assoc.mem(key, _list) ? list.assoc(key, _list) : null()
  end

if (m["jingle_mode"] != "true") then

  pre_artist = null_list("artist", m)
  pre_title = null_list("title", m)

  artist = ref("")
  title = ref("")


     if pre_artist == null() then
        if string.contains(substring=" - ", m["title"]) then
            let (a, t) = string.split.first(separator=" - ", m["title"])
       	    title := t
            artist := a
        end
     else
            title := pre_title
            artist := pre_artist
     end
 try

  process.run("telegram-send-omfm 'Now playing: #{artist()} - #{title()}'")

 catch error do
  handle_error(error)
 end

end

end

omfm_0.on_metadata(telegram_omFM)

Magic! :) Could you turn it into science? Thanks!

[toots]

Wait. I think I got it!

[gAlleb]

Here is minimum reproduction.
2.2.5 - OK.
2.3.0 - doesn't work

settings.log.stdout := true
settings.log.level := 3
radio = playlist(reload_mode="watch", "/music")

 def write_json_nowplaying(radio)

  def write_data()

  def null_float(f)
    f == infinity ? null() : f
  end

  def null_list(key, _list)
    list.assoc.mem(key, _list) ? list.assoc(key, _list) : null()
  end

  m = radio.last_metadata() ?? []
 
  file_duration = null.get(default=0.0, request.duration(m["filename"]))

  pre_artist = null_list("artist", m)
  
  pre_title = null_list("title", m)
  
  default_stream_title = "Default" # null()
  stream_title =
  if pre_title == null() then
    default_stream_title
  elsif pre_artist == null() then
    pre_title
  else
    "#{pre_artist} - #{pre_title}"
  end

  artist = ref("")
  title = ref("")


     if pre_artist == null() then
        if string.contains(substring=" - ", m["title"]) then
            let (a, t) = string.split.first(separator=" - ", m["title"])
       	    title := t
            artist := a
        end
     else
            title := pre_title
            artist := pre_artist
     end


  np = {

    now_playing = {
      played_at = null_list("on_air_timestamp", m),
      played_at_timestamp = null_list("on_air_timestamp", m),
      played_at_date_time = null_list("on_air", m),
      duration = null_float(source.duration(radio)),
      elapsed = null_float(source.elapsed(radio)),
      remaining = null_float(source.remaining(radio)),
      playlist = null_list("playlist", m),
      filename = null_list("filename", m),

      song = { 
           	text = stream_title,
     	  	artist = artist(),
         	title = title(),
          	album = null_list("album", m),
 	 	genre = null_list("genre", m),
        	song_duration = null_float(file_duration)
	     }     
       }  
  }


#if (m["jingle_mode"] != "true") then
#send_mq_event(json.stringify(np, compact=true))
#end
 
 end

  thread.run(write_data, every=1.0, fast=false)
end
write_json_nowplaying(radio)

def get_metadata(_)

  def null_float(f)
    f == infinity ? null() : f
  end

  def null_list(key, _list)
    list.assoc.mem(key, _list) ? list.assoc(key, _list) : null()
  end

  m = radio.last_metadata() ?? []

  file_duration = null.get(default=0.0, request.duration(m["filename"]))

  pre_artist = null_list("artist", m)
  
  pre_title = null_list("title", m)
  
  default_stream_title = "Default" # null()
  stream_title =
  if pre_title == null() then
    default_stream_title
  elsif pre_artist == null() then
    pre_title
  else
    "#{pre_artist} - #{pre_title}"
  end

  artist = ref("")
  title = ref("")

     if pre_artist == null() then
        if string.contains(substring=" - ", m["title"]) then
            let (a, t) = string.split.first(separator=" - ", m["title"])
       	    title := t
            artist := a
        end
     else
            title := pre_title
            artist := pre_artist
     end

  data = {

    now_playing = {
      played_at = null_list("on_air_timestamp", m),
      played_at_timestamp = null_list("on_air_timestamp", m),
      played_at_date_time = null_list("on_air", m),
      duration = null_float(source.duration(radio)),
      elapsed = null_float(source.elapsed(radio)),
      remaining = null_float(source.remaining(radio)),
      playlist = null_list("playlist", m),
      filename = null_list("filename", m),

      song = { 
           	text = stream_title,
     	  	artist = artist(),
         	title = title(),
          	album = null_list("album", m),
 	 	genre = null_list("genre", m),
        	song_duration = null_float(file_duration)
	     }   
     } 
  }
 try

  http.response(
    status_code=200,
    headers=[
                ("Content-Type", "application/json"),
                ("Access-Control-Allow-Origin","*")
            ],
    content_type="application/json; charset=UTF-8",
    data=json.stringify(data, compact=true) ^ "\n"
  )

 catch error do

  log.severe(error.message, label="http")
  http.response(
    status_code=500,
    content_type="application/json; charset=UTF-8",
    data='{"status":"error","message":"Failed to serialize response data"}' ^ "\n"
  )
  end
end
harbor.http.register.simple("/nowplaying", get_metadata, port=8089, method="GET")
radio = mksafe(radio)
output.dummy(radio)

At test.liq, line 83, char 22-27:
write_json_nowplaying(radio)

Error 5: this value has type
  _.{last_metadata : (...) -> _?} (inferred at test.liq, line 3, char 8-87)
but it should be a subtype of
  _.{last_metadata? : (...) -> [_]}

The above points to playlist line3

Then, this kind of errors point to m = radio.last_metadata() ?? []

Error 5: this value has type
  _? (inferred at ...)
but it should be a subtype of
  [_]

[toots]

Fix should be pending here: #3862

[gAlleb]

Thanks a lot, @toots! I'll give it try.

[gAlleb]

That does work! Thanks.

[gAlleb]

Got a question.
Say I save song history during playback and then send it to API.

songHistory = ref([])

def save_history(m, ~last=10)
  def null_list(key, _list)
    list.assoc.mem(key, _list) ? list.assoc(key, _list) : ""
  end
  def null_float(f)
    f == infinity ? null() : f
  end
  
  pre_artist = null_list("artist", m)
  pre_title = null_list("title", m)
 
  default_stream_title = "Default" # null()
  stream_title =
  if pre_title == "" then
    default_stream_title
  elsif pre_artist == "" then
    pre_title
  else
    "#{pre_artist} - #{pre_title}"
  end

  artist = ref("")
  title = ref("")
     if pre_artist == "" then
        if string.contains(substring=" - ", m["title"]) then
            let (a, t) = string.split.first(separator=" - ", m["title"])
       	    title := t
            artist := a
        end
     else
            title := pre_title
            artist := pre_artist
     end

if (m["jingle_mode"] != "true") then
  sh = {

      played_at = null_list("on_air_timestamp", m),
      played_at_timestamp = null_list("on_air_timestamp", m),
      played_at_date_time = null_list("on_air", m),
      playlist = null_list("playlist", m),
      filename = null_list("filename", m),

      song = {
		text = stream_title,
		artist = artist(),
    		title = title(),
		album = null_list("album", m),
 	 	genre = null_list("genre", m)

	   }
  }
  songHistory := sh::songHistory()

  if list.length(songHistory()) > last then
    songHistory := list.prefix(last,songHistory())
  end  
end 

end
s.on_metadata(save_history)

What can I do to restore it when LS restarts? Save it to json and on restart parse it? Sounds complicated - there are 10 positions and I have no clue how.
The idea is when LS restarts songHistory = ref([]) gets populated with restored data and then changes with s.on_metadata(save_history) as usual.

[toots]

Yeah it's a valid concern. This has prompted me to revive the typeof feature. Until now I didn't see any useful use of it but now I do.. Work is being done here: #4037

With it, you should be able to do:

songHistory = ref([])

try
  let json.parse (savedHistory : typeof songHistory()) = file.contents("/path/to/data.json")
  songHistory := savedHistory
catch _ do
  ()
end

[gAlleb]

Sounds futuristic! Thanks, toots!
Looking forward.

[gAlleb]

@toots, Tried out typeof branch. Works great. Thanks!

songHistory = ref([])

def restore_history() 
try
  let json.parse (savedHistory : typeof songHistory()) = file.contents("song_history.json")
  songHistory := savedHistory
catch _ do
  ()
end
end

thread.run(restore_history, fast=false)