Windows Help

[refriedfood]

I've been trying to transfer my station over to a better solution for a few days now, and I'm at a loss. I want to run my icecast station via commandline on a windows box, instead of the current gui, but I'm having nothing but problems. I've read through the documents, and if I don't get a syntax error, I get a random error from 0, localhost not found, to Error 8: Unsupported format, etc.

Before I even continue to hack away at this, which I might add has no useful instructions out there on how to setup on a windows platform, I want to know if the following is possible:
Stream to an icecast server, append a title to each metadata that is playing (i.e. Song - song [ blah radio ]), run or at least transcode to 192kbps on the fly as mp3s from a playlist, and is stable enough to run weeks long without crashing, and not worry about the system having a soundcard (which it does not).

Where I last left off:
I tried to run a test.liq (liquidsoap test.liq) with the following:

set("log.file.path","log.log")
myplaylist = playlist("test.m3u")
radio = myplaylist
radio = fallback(track_sensitive = false, [radio])
output.icecast(%mp3,
  host = "localhost", port = 2121,
  password = "password", mount = "basic-radio.ogg",
  radio)

And received the following:
At 2.liq, line 18, char 15-19: output.icecast(%mp3,
Error 8: Unsupported format: %mp3()

Any help would be great.

[toots]

Hi @refriedfood. We need to find a better way to communicate about this. The windows build of liquidsoap is limited to only the %ffmpeg encoder. However, the %ffmpeg encoder supports a wide range of formats so this should not limit the users. In your case, you should be able to do this:

set("log.file.path","log.log")
myplaylist = playlist("test.m3u")
radio = myplaylist
radio = fallback(track_sensitive = false, [radio])
output.icecast(
  %ffmpeg(
    format="mp3",
    %audio(codec="libmp3lame")
  ),
  host = "localhost", port = 2121,
  password = "password", mount = "basic-radio.ogg",
  radio)

[GeorgGa]

The windows build of liquidsoap is limited to only the %ffmpeg encoder.

Is this information present somewhere in the documentation (big fan of it btw, it's very detailed and clean)? If not, may I suggest to add it to the Encoding formats section, please?

II got a mp3 stream working with the "libmp3lame" encoder and FFmpeg (like in the snippet above) on my Windows machine, but wondered why I couldn't change it to some Ogg vorbis or flac encoding without FFmpeg. The log always told me "Error 8: Unsupported format". But now that I found this old thread, I know why :)

[toots]

@GeorgGa For ogg/vorbis, it should be something like this:

%ffmpeg(
  format="ogg",
  %audio(codec="libvorbis")
)

I have added a note on the encoding formats page, great suggestion thanks!

[refriedfood]

Thanks, toots, I appreciate the help.

I receive the following error when I run your config with liquidsoap 1.liq

[Oct 03 21:22 : ](exception: Error in 1.conf line 1; Invalid word character)

Then the console is unresponsive, nor does it make any connections.

Is there something special I'm missing/need using your method?

[toots]

Hi. I'm not sure. This looks like some issue with the script encoding/text content?

[refriedfood]

What do you think it could be? I tried to remove everything but the following in the m3u:
C:\Users\music\Misc\Soft Eyez - 03 - Tina.mp3

And it spit out this now:

At 3.liq, line 4, char 8-50:
radio = fallback(track_sensitive = false, [radio])

Error 7: Invalid value:
That source is fallible

[toots]

You should add faillible=true to output.icecast. For more details about these issues, I recommend the FAQ here: https://www.liquidsoap.info/doc-2.1.2/faq.html and for a longer, deeper version, the liquidsoap book: https://www.liquidsoap.info/doc-dev/book.html

[refriedfood]

I already tried reading that, that's why I'm here. I read and configured the most primitive version for my server and it doesn't work. I'm simply not getting it. I'm not a coder, nor do I frequent use linux. Most of this is literally another language to me that doesn't make a lick of sense in its schematic documentation. One error leads to another and then another with no answers. All I want is to do is push a playlist to a icecast server, and maybe, if I'm lucky, have it crossfade by 3 seconds. Why is it so difficult?

[refriedfood]

After toiling away with this, and giving up hope on github and the documentation on the website, which really should be rewritten, I decided to place my config.liq results here for anyone who isn't a coder but perhaps a musician, etc that find it useful. It's for Windows x64 version 2.1.2:

#all directories/files are NOT in read-only mode
set("log.file.path","./log/log.txt")
 
# define playlog - this is for the recording of the track randomizations, and the file in which will clear itself every 24hours
l = playlog(duration = 86400., persistency = "./log/playlog.txt", hash = fun (m) -> metadata.artist(m))
 
# Last.fm Scrobbling user info - this is the log in information if you are going to stream your station and have last.fm entries
    lfm_enable = true
    lfmuser = "yourLASTFMusername"
    lfmpass = "yourLASTFMpassword"
 
# Last.fm scrobble function -- this is the actual, working, scrobbler for last fm
def lastfm.scrobble(m) =
    if lfm_enable then
        audioscrobbler.submit(user=lfmuser,password=lfmpass,m)
        audioscrobbler.nowplaying(user=lfmuser,password=lfmpass,m)
    end
end
 
# function to change title -- this appends a station title to the title being shown to the listeners. i.e. Artis - Song (your station's name)
def append_title(m) =
    # Grab the current title
    title = m["title"]
    # Return a new title metadata
    [("title","#{title} (You Station's Name)")]
end
 
# function to check if the artist has been played the last hour -- this is a true randomization mode that prevents an aritst from
# being played every (seconds), currently at 900 (15min), and will spit out to the console a dupe message that you 
# can compare to the playlog.txt (up top) for adjusting, if needed
def check(r)
    m = request.metadata(r)
    if l.last(m) < 900. then
        print("DUPE ARTIST HAS BEEN SKIPPED")
        l.add(m)
        false
    else
        l.add(m)
        true
     end
end

 
# define playlist -- this is where your music or playlist is stored and the mode it's played in
myplaylist = playlist(check_next=check, "C:/mymusic")
#myplaylist = playlist(check_next=check, "music.m3u", mode="normal")
radio = myplaylist
 
# temperamental crossfading -- this function needs to be fixed by the developers as it sometimes causes pauses 
# between fade starts, but removing fade_out = 2., fade_in = 2., and leaving duration can fix the issue
radio = crossfade(duration = 4., radio)

# perform scrobble -- this activates the lastfm submission
radio.on_metadata(lastfm.scrobble)
 
# Apply metadata.map to radio using append_title -- this applies the Your Station's Name appending to the track title
radio = metadata.map(append_title, radio)

# This function is supposed to append every track from the start of the script to when it finished into a file, showing each track that 
# has been played per line, but it currently doesn't work and only overwrites onto a single line each track. Its whole 
# purpose of this was to log when and what song the script started with and what it crashed on, so trouble shooting could be done. 
# It is left uncommented to keep the console displaying the current track being played
def log_song(m)
    t = time.local()
    artist = m["artist"]
    title = m["title"]
    print("#{t.hour}:#{t.min} :: #{artist} - #{title}")
    file.write(data="#{t.month}/#{t.day}/#{t.year} :: #{t.hour}:#{t.min} :: #{artist} - #{title}\n", append=true, "./log/songs.txt")
end
radio.on_metadata(log_song)
 
# make playlist safe -- this prevents the program from crashing if there is a specified song but the song doesn't 
# exist in the directory (it keeps playing)
radio = mksafe(radio)
 
# output -- this, finally, is where all of the hassle before it is spitting out through -- your ice/shoutcast information 
# and FFMPEG as its transcoder
output.icecast(
    %ffmpeg(format="mp3",
    %audio(codec="libmp3lame", b="192k")),
    host = "localhost",
    port = 1234,
    password = "yourpassword",
    mount = "filename",
    name="your station name",
    description="your station's description",
    genre="your station's genres",
    url="https://stationurl.com",
    radio
)

Overall, even though it took some brain bleeding to figure out, I think liquidsoap is a great tool. It is definitely better than mpd or any other clone, and I hope someone out there finds this useful. it should work by default, all you have to do is configure what you want, with your information, and then save it to a liq file and run as "liquidsoap mine.liq" etc.