How to record audio (output.file) from input.harbor?

[rrolla]

I want to record from input.harbor but cannot manage how can I define source before onConnect method.

Version: liquidsoap_2.0.4-ubuntu-focal-3_amd64.deb

Code example

djBlank = blank(id="dj")
dj = ref((djBlank:source))

def onConnect
    output.file(%mp3, "archive/%Y-%m-%d/%H-%M-%S.mp3", mksafe(!dj), reopen_when={0m})
    null()
end

dj := input.harbor(buffer=12., debug=true, on_connect=onConnect, password="hackme", port=8005, "dj")

This code throws error:

rolla-liquidsoap | At /home/liquidsoap/config/input/dj-input.liq, line 9, char 54-63:
rolla-liquidsoap | dj := input.harbor(buffer=12., debug=true, on_connect=onConnect, password="hackme", port=8005, "dj")
rolla-liquidsoap | 
rolla-liquidsoap | Error 5: this value has type
rolla-liquidsoap |   _? (inferred at /home/liquidsoap/config/input/dj-input.liq, line 6, char 4-10)
rolla-liquidsoap | but it should be a subtype of the type of the value at /usr/share/liquidsoap/2.0.4/libs/telnet.liq, line 101, char 26-47
rolla-liquidsoap |   (_) -> _
rolla-liquidsoap exited with code 1

[rrolla]

Okay I figured out myself, that the problem was with ref declaration and that I must add one argument headers to the onConnect function

dj = ref(blank())

def record()
    output.file(%mp3(samplerate=44100, bitrate=320), "content/archive/%Y-%m-%d/%H-%M-%S.mp3", mksafe(!dj), reopen_when={0m})
    {}
end

def startRecord()
    thread.run((fun() -> begin record() end))
end

def onConnect(headers)
    startRecord()
    {}
end

dj := input.harbor(on_connect=onConnect, password="hackme", port=8005, "dj")

[toots]

Hmm. If this works this is cool but I'm curious why you need to change the source?

[rrolla]

@toots Because I want to start recording when DJ connects and if I don't use dj as a reference in onConnect method dj is not yet declared, because it does after onConnect. I hope you got the point.

[toots]

Defintely. But in this case, I would suggest to pivot around using a start/stop command reference like this:

onConnect = ref(fun () -> ())

dj = input.harbor(
  on_connect={!onConnect()},
  password="hackme",
  port=8005, 
  "dj"
)

recordingSource = output.file(
  %mp3(samplerate=44100, bitrate=320),
  "content/archive/%Y-%m-%d/%H-%M-%S.mp3",
  dj,
  reopen_when={0m},
  start=false
)

onConnect := fun () -> recordingSource.start()

Or, perhaps even simpler, leave the task of starting/stopping the output based on when the DJ source is available:

dj = input.harbor(
  password="hackme",
  port=8005, 
  "dj"
)

recordingSource = output.file(
  %mp3(samplerate=44100, bitrate=320),
  "content/archive/%Y-%m-%d/%H-%M-%S.mp3",
  dj,
  reopen_when={0m},
  fallible=true,
)

[rrolla]

thanks for the updated examples. As I need also hit laravel API I will try to use your first example