How to add output audio vizualisation over an output in liquidsoap format ?

[novus213]

Hi,

I discover liquisoap.
I have an azuracast server, I use the script that one of the admins proposed to the community (https://gist.githubusercontent.com/SlvrEagle23/5dbfb4dbc1846055c9ab07a7c685899c/raw/584ba182b52e0598f1added00c0b5280b0db53b8/video_stream.liq)
I would like to add an audio wave effect on top of my output rendering.
In the liquisoap api documentation I found ffmpeg.filter.showwaves but I can't transcribe it.
I started from an example I found online here, which is not in liquidsoap format:
ffmpeg ......
[0:a]showwaves=mode=cline:s=1920x480:[email protected]|[email protected]:scale=cbrt:r=25[waves];
[image][waves]overlay=0:600[bg];
......

I would like to know how this translates into liquidsoap?

have try something but, have feeling that it's not good...

def add_vizu(strm,r) =
  def mkfilter(graph) =
    vizualization = ffmpeg.filter.showwaves(mode="cline",s="1920x480",colors="[email protected]|[email protected]",scale="cbrt",r=25,strm,r)

    v = ffmpeg.filter.overlay(graph, vizualization,
      y="0",
      x="600"
    )

    ffmpeg.filter.video.output(graph, v)
  end

  ffmpeg.filter.create(mkfilter)
end

videostream = add_vizu(videostream, radio)


# Add the audio stream
videostream = mux_video(video=videostream, radio)


# Output 
enc = %ffmpeg(
    format="flv", 
    %video.raw(codec="libx264", pixel_format="yuv420p", b="300k", preset="superfast", r=25, g=50),
    %audio(codec="libmp3lame", samplerate=44100, b="160k")
)

output.url(fallible=true, url=urlyt, enc, videostream)

regards

[toots]

This works with the latest main. There are some initial glitches that I will review at some point in the future but it definitely works once it's started and settled:

s = playlist("/path/to/playlist")

def show_waves(s) =
  def mkfilter(graph)
    a = ffmpeg.filter.audio.input(graph, s)

    let ([a, a'], _) = ffmpeg.filter.asplit(graph, a)
    v = ffmpeg.filter.showwaves(
      s="1280x720",
      mode=1,
      graph, a)
    v = ffmpeg.filter.format(pix_fmts="yuv420p", graph, v)
    v = ffmpeg.filter.video.output(graph, v)

    # Remove this when https://github.com/savonet/liquidsoap/issues/2384 is closed:
    a' = ffmpeg.filter.anull(graph, a')
    a' = ffmpeg.filter.audio.output(graph, a')

    (a', v)
  end

  let (a, v) = ffmpeg.filter.create(mkfilter)
  mux_video(video=v, a)
end

s = show_waves(s)

[novus213]

thanks lot !

i have fix the a' cuz, its generated me an error.
i have adapt to my code but i have a syntax error
At line 390, char 9: Error 3: Syntax error!

thank you in advance for your help

station_base_dir = "path"

urlyt = "rtmp://a.rtmp.youtube.com/live2/xxxxxx"

url = "rtmp://cdg10.contribute.live-video.net/app/xxxxxx"


# Fetch and encode video
video_file = station_base_dir ^ "/media/videostream/video.mp4"

# Write now playing to the video file
font_file = station_base_dir ^ "/media/videostream/font.ttf"

# Customize where the text appears on the screen
font_size = 25
font_x = 225
font_y = 650
font_color = 0x000000

# Add Now Playing metadata
nowplaying = ref("")
def update_nowplaying(m)
    nowplaying := m["artist"] ^ " - " ^ m["title"]
end
radio.on_metadata(update_nowplaying)

# Method to overlay now playing text
def add_nowplaying_text(d, s) =
  def mkfilter(graph)
    v = video.add_text.ffmpeg.raw(color=font_color,font=font_file,size=font_size,speed=70,x=font_x,y=font_y,graph=graph,d,s)
    ffmpeg.filter.video.output(graph, v)
  end
  ffmpeg.filter.create(mkfilter)
end

videostream = single(video_file)

# Method to overlay with audio vizualizer
def show_waves(s) =
  def mkfilter(graph)
    a = ffmpeg.filter.audio.input(graph, s)

    let ([a, a], _) = ffmpeg.filter.asplit(graph, a)
    v = ffmpeg.filter.showwaves(
      s="1280x720",
      mode=1,
      graph, a)
    v = ffmpeg.filter.format(pix_fmts="yuv420p", graph, v)
    v = ffmpeg.filter.video.output(graph, v)

    # Remove this when https://github.com/savonet/liquidsoap/issues/2384 is closed:
    a = ffmpeg.filter.anull(graph, a)
    a = ffmpeg.filter.audio.output(graph, a)

    (a, v)
  end

  let (a, v) = ffmpeg.filter.create(mkfilter)
  mux_video(video=v, a)
end

videostream = show_waves(radio)

videostream = add_nowplaying_text({!nowplaying}, videostream)

# Add the audio stream
videostream = mux_video(video=videostream, radio)

# Output
enc = %ffmpeg(
    format="flv", 
    %video.raw(codec="libx264", pixel_format="yuv420p", b="300k", preset="superfast", r=25, g=50),
    %audio(codec="libmp3lame", samplerate=44100, b="160k")
)

output.url(fallible=true, url=urlyt, enc, videostream)
output.url(fallible=true, url=url, enc, videostream)

[toots]

Woof that's a tricky combination!

I just pushed some changes to the latest main that you will need to make this work.

One you've updated to the latest main, you should try this:

station_base_dir = "path"

urlyt = "rtmp://a.rtmp.youtube.com/live2/xxxxxx"

url = "rtmp://cdg10.contribute.live-video.net/app/xxxxxx"


# Fetch and encode video
video_file = station_base_dir ^ "/media/videostream/video.mp4"

# Write now playing to the video file
font_file = station_base_dir ^ "/media/videostream/font.ttf"

# Customize where the text appears on the screen
font_size = 25
font_x = 225
font_y = 650
font_color = 0xffffff

nowplaying = ref("")

def update_nowplaying(m)
    nowplaying := m["artist"] ^ " - " ^ m["title"]
end
radio.on_metadata(update_nowplaying)

def apply_filters(s) =
  on_frame = ref (fun () -> ())
  on_metadata = ref (fun (_) -> ())
  s = source.on_metadata(s, fun (m) -> begin
    fn = !on_metadata
    fn(m)
  end)
  s = source.on_frame(s, fun () -> begin
    fn = !on_frame
    fn()
  end)

  def mkfilter(graph)
    a = ffmpeg.filter.audio.input(graph, s)

    let ([a1, a2], _) = ffmpeg.filter.asplit(graph, a)
    v = ffmpeg.filter.showwaves(
      s="1280x720",
      mode=1,
      graph, a1)

    v = video.add_text.ffmpeg.raw.filter(
      color=font_color,font=font_file,size=font_size,speed=70,x=font_x,y=font_y,graph=graph,{!nowplaying},v
    )

    on_frame := v.on_change
    on_metadata := v.on_metadata

    v = ffmpeg.filter.format(pix_fmts="yuv420p", graph, v)
    v = ffmpeg.filter.video.output(graph, v)

    # Remove this when https://github.com/savonet/liquidsoap/issues/2384 is closed:
    a = ffmpeg.filter.anull(graph, a2)
    a = ffmpeg.filter.audio.output(graph, a)
  end

  let (a, v) = ffmpeg.filter.create(mkfilter)
  mux_audio(audio=a, v)
end

videostream = apply_filters(radio)

# Output
enc = %ffmpeg(
    format="flv",
    %video.raw(codec="libx264", pixel_format="yuv420p", b="300k", preset="superfast", r=25, g=50),
    %audio.raw(codec="libmp3lame", samplerate=44100, b="160k")
)

output.url(fallible=true, url=urlyt, enc, videostream)
output.url(fallible=true, url=url, enc, videostream)

[novus213]

Wooh thanks to your help !
Im really sorry, i have tested and i have this error

At /var/azuracast/stations/xxxxxxxxxx/config/liquidsoap.liq, line 390, char 9:
    let ([a1, a2], _) = ffmpeg.filter.asplit(graph, a)

Error 3: Syntax error!

i have tried this from the doc but same
 s = ffmpeg.filter.audio.input(graph, s)
     let (audio, _) = ffmpeg.filter.asplit(outputs=2, graph, s)
  let [a1, a2] = audio

thank you in advance for your help

[toots]

Yeah, that probably indicates that you are not using the latest main code.