build.gradle

plugins {
    id 'java'
    id 'distribution'
}

group 'org.citydb.ade'
version '1.5.0'
description 'i-Urban Revitalization ADE extension for the 3DCityDB'

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(11)
    }
    compileJava {
        options.release = 8
    }
}

configurations {
    citygml4j
}

repositories {
    maven {
        url 'https://citydb.jfrog.io/artifactory/maven'
    }
    maven {
        url 'https://repo.osgeo.org/repository/release'
    }
    mavenCentral()
}

dependencies {
    implementation 'org.citydb:impexp-client-gui:5.0.0-SNAPSHOT'
    implementation 'org.citygml4j.ade:iur-ade-citygml4j:1.4.1'

    citygml4j('org.citygml4j.ade:iur-ade-citygml4j:1.4.1') {
        transitive = false
    }
}

jar {
    manifest {
        attributes('Implementation-Title': project.name,
                'Implementation-Version': project.version
        )
    }
    into('META-INF') {
        from 'LICENSE'
    }
}

distributions.main {
    distributionBaseName  = 'iur-ade'
    contents {
        from 'README.md'
        into('lib') {
            from jar
            from configurations.citygml4j
        }
        into('schema-mapping') {
            from 'resources/database/schema-mapping'
        }
        into('3dcitydb') {
            from 'resources/database/3dcitydb'
        }
    }
}