build.gradle

buildscript {
    repositories {
        mavenCentral()
    }
}

plugins {
    id "java"
    id "com.google.protobuf" version "0.9.4"
    id 'com.github.johnrengelman.shadow' version '8.1.1'
}

// Use Java 11 since CP Docker images package Java 11 as of CP 7.3.x
sourceCompatibility = JavaVersion.VERSION_11
targetCompatibility = JavaVersion.VERSION_11
compileJava.options.compilerArgs << "-parameters"
version = "0.0.1"

repositories {
    mavenCentral()


    maven {
        url "https://packages.confluent.io/maven"
    }
}

dependencies {
    implementation 'io.confluent.ksql:ksqldb-udf:7.4.0'
    implementation 'org.apache.kafka:kafka_2.13:3.5.1'
    implementation 'org.apache.kafka:connect-api:3.5.1'
    implementation 'com.google.protobuf:protobuf-java:3.24.4'
    implementation 'io.github.zabuzard.closy:closy:1.2.1'
    testImplementation(platform('org.junit:junit-bom:5.10.0'))
    testImplementation('org.junit.jupiter:junit-jupiter')
}

task copyJar(type: Copy) {
    from jar
    into "extensions/"
}

build.dependsOn copyJar

test {
    useJUnitPlatform()
    testLogging {
        outputs.upToDateWhen { false }
        showStandardStreams = true
        exceptionFormat = "full"
    }
}

shadowJar {
    archiveBaseName = "acdp-ksql-udfs"
    archiveClassifier = ""
    destinationDirectory = file("extensions")
    dependencies {
        include(dependency("org.apache.kafka_2.13:3.5.1"))
        include(dependency("org.apache.kafka:connect-api:3.5.1"))
        include(dependency("com.google.protobuf:protobuf-java:3.24.4"))
        include(dependency("io.confluent.ksql:ksqldb-udf:7.4.0"))
        include(dependency("io.github.zabuzard.closy:closy:1.2.1"))
    }
}