dependencies.gradle

allprojects {
    repositories {
        google()
        mavenCentral()
    }
}

ext {
    // LIBRARY VERSION
    androidVersionCode          = 20
    androidVersionName          = "4.3.1"

    // LIBRARY INFORMATION
    libraryGroupId              = 'com.mikhaellopez'
    libraryArtifactId           = 'circularimageview'
    libraryVersion              = androidVersionName
    libraryName                 = "CircularImageView"
    libraryDesc                 = "This is an Android project allowing to realize a circular ImageView in the simplest way possible."

    // ANDROID VERSION
    androidCompileSdkVersion    = 33
    androidMinSdkVersion        = 14
    androidTargetSdkVersion     = 33

    // KOTLIN
    kotlinStdlib                = "org.jetbrains.kotlin:kotlin-stdlib:$ext.kotlin_version"

    // ANDROID LIB
    androidXAppCompat           = "androidx.appcompat:appcompat:1.5.0"

    // UI
    lobsterPicker               = "com.larswerkman:lobsterpicker:1.0.1"

    // DEPENDENCY CHECK STRATEGY
    dependencyUpdatesStrategy = {
        def isNonStable = { String version ->
            def stableKeyword = ['RELEASE', 'FINAL', 'GA'].any { keyword ->
                version.toUpperCase().contains(keyword)
            }
            def regex = /^[0-9,.v-]+(-r)?$/
            return !stableKeyword && !(version ==~ regex)
        }
        componentSelection {
            all {
                if (isNonStable(it.candidate.version) && !isNonStable(it.currentVersion)) {
                    reject('Release candidate')
                }
            }
        }
    }

}