flake.nix

{
  description = "NuhxBoard flake";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";

    crane.url = "github:ipetkov/crane";

    fenix = {
      url = "github:nix-community/fenix";
      inputs.nixpkgs.follows = "nixpkgs";
      inputs.rust-analyzer-src.follows = "";
    };

    flake-utils.url = "github:numtide/flake-utils";

    advisory-db = {
      url = "github:rustsec/advisory-db";
      flake = false;
    };
  };

  outputs = {
    self,
    nixpkgs,
    crane,
    fenix,
    flake-utils,
    advisory-db,
    ...
  }:
    flake-utils.lib.eachDefaultSystem (system: let
      pkgs = nixpkgs.legacyPackages.${system};

      inherit (pkgs) lib;

      craneLib = crane.mkLib pkgs;

      iconFilter = path: (builtins.match ".*NuhxBoard.png$" path) != null;
      iconOrCargo = path: type: (iconFilter path) || (craneLib.filterCargoSources path type);
      src = lib.cleanSourceWith {
        src = ./.;
        filter = iconOrCargo;
        name = "source";
      };
      commonArgs = {
        inherit src;
        strictDeps = true;

        buildInputs = with pkgs;
          [
            expat
            fontconfig
            freetype
            freetype.dev
            libGL
            pkg-config
            xorg.libX11
            xorg.libXcursor
            xorg.libXi
            xorg.libXrandr
            xorg.libXtst
            openssl
            wayland
            libxkbcommon
            libevdev
          ]
          ++ lib.optionals pkgs.stdenv.isDarwin [
            pkgs.libiconv
          ];

        nativeBuildInputs = with pkgs; [copyDesktopItems pkg-config makeWrapper];
      };

      craneLibLLvmTools =
        craneLib.overrideToolchain
        (fenix.packages.${system}.complete.withComponents [
          "cargo"
          "llvm-tools"
          "rustc"
        ]);

      # Build *just* the cargo dependencies, so we can reuse
      # all of that work (e.g. via cachix) when running in CI
      cargoArtifacts = craneLib.buildDepsOnly commonArgs;

      # Build the actual crate itself, reusing the dependency
      # artifacts from above.
      nuhxboard = craneLib.buildPackage (commonArgs
        // {
          inherit cargoArtifacts;
        }
        // {
          desktopItems = [
            (pkgs.makeDesktopItem {
              name = "NuhxBoard";
              desktopName = "NuhxBoard";
              comment = "Cross-platform input visualizer";
              icon = "NuhxBoard";
              exec = "nuhxboard";
              terminal = false;
              keywords = ["Keyboard"];
              startupWMClass = "NuhxBoard";
            })
          ];

          postInstall = ''
            install -Dm644 ${src}/NuhxBoard.png $out/share/icons/hicolor/128x128/apps/NuhxBoard.png
            wrapProgram $out/bin/nuhxboard --prefix LD_LIBRARY_PATH : "${pkgs.lib.makeLibraryPath commonArgs.buildInputs}"
          '';
        });
    in {
      checks = {
        # Build the crate as part of `nix flake check` for convenience
        nuhxboard = nuhxboard;

        # Run clippy (and deny all warnings) on the crate source,
        # again, reusing the dependency artifacts from above.
        #
        # Note that this is done as a separate derivation so that
        # we can block the CI if there are issues here, but not
        # prevent downstream consumers from building our crate by itself.
        nuhxboard-clippy = craneLib.cargoClippy (commonArgs
          // {
            inherit cargoArtifacts;
            cargoClippyExtraArgs = "--all-targets -- --deny warnings";
          });

        nuhxboard-doc = craneLib.cargoDoc (commonArgs
          // {
            inherit cargoArtifacts;
          });

        # Check formatting
        nuhxboard-fmt = craneLib.cargoFmt {
          inherit src;
        };

        # Audit dependencies
        nuhxboard-audit = craneLib.cargoAudit {
          inherit src advisory-db;
        };

        # Audit licenses
        nuhxboard-deny = craneLib.cargoDeny {
          inherit src;
        };

        # Run tests with cargo-nextest
        # Consider setting `doCheck = false` on `nuhxboard` if you do not want
        # the tests to run twice
        nuhxboard-nextest = craneLib.cargoNextest (commonArgs
          // {
            inherit cargoArtifacts;
            partitions = 1;
            partitionType = "count";
          });
      };

      packages =
        {
          default = nuhxboard;
        }
        // lib.optionalAttrs (!pkgs.stdenv.isDarwin) {
          nuhxboard-llvm-coverage = craneLibLLvmTools.cargoLlvmCov (commonArgs
            // {
              inherit cargoArtifacts;
            });
        };

      apps.default = flake-utils.lib.mkApp {
        drv = nuhxboard;
      };

      devShells.default = craneLib.devShell {
        # Inherit inputs from checks.
        checks = self.checks.${system};

        packages = with pkgs; [
          cargo-dist
          cargo-release
        ];

        LD_LIBRARY_PATH = "${pkgs.lib.makeLibraryPath commonArgs.buildInputs}";
      };
    });
}