Embed run command lang highlight and LSP with Neovim and otter.nvim

[EricDriussi]

I wrote a couple of lines to get treesitter to highlight the code in the run command and used otter.nvim to get full LSP support for it as well (autocompletion, diagnostics, the whole thing):

Here a non-mise toml file is shown on the right to show it only affects mise.toml files.

For those interested, I added a couple of treesitter toml injections:

; extends

(pair
	(bare_key) @key (#eq? @key "run")
	(string) @injection.content @injection.language

	(#match? @injection.language "^\"\"\"\n#!/.*")
	(#gsub! @injection.language "^\"\"\"%s*#!/usr/bin/env%s([^%c]+).*" "%1")
	(#offset! @injection.content 0 3 0 -3)
	(#is-mise?)
)

(pair
	(bare_key) @key (#eq? @key "run")
	(string) @injection.content

	(#match? @injection.content "^\"\"\".*")
	(#not-match? @injection.content "^\"\"\"\n#!/")
	(#offset! @injection.content 0 3 0 -3)
	(#set! injection.language "bash")
	(#is-mise?)
)

(pair
	(bare_key) @key (#eq? @key "run")
	(string) @injection.content

	(#not-match? @injection.content "^\"\"\"")
	(#offset! @injection.content 0 1 0 -1)
	(#set! injection.language "bash")
	(#is-mise?)
)

And configured otter.nvim like so:

{
"jmbuhr/otter.nvim",
dependencies = {
	"nvim-treesitter/nvim-treesitter",
},
config = function()
	vim.api.nvim_create_autocmd({ "FileType" }, {
		pattern = { "toml" },
		callback = function()
			require("vim.treesitter.query").add_predicate("is-mise?", function(_, _, bufnr, _)
				local filepath = vim.api.nvim_buf_get_name(tonumber(bufnr) or 0)
				local filename = vim.fn.fnamemodify(filepath, ":t")
				return filename == "mise.toml"
			end, {})
			require("otter").activate()
		end,
	})
end,
},

The injections set the lang to bash for one-liners and multi-line commands with no shebang. If it's multi-line and has a shebang, get the lang set in the shebang.
This can of course be extended to support the shell property (currently ignored).

I'm happy to add this to the docs if it's of any help/interest.

[jdx]

seems fit for a neovim cookbook