build.gradle.kts

plugins {
    kotlin("multiplatform") version "1.8.10"
    id("org.jetbrains.compose") version "1.4.0-alpha01-dev980"
}

repositories {
    mavenCentral()
    google()
    maven("https://maven.pkg.jetbrains.space/public/p/compose/dev")
}

kotlin {
    jvm() //for common tests
    js(IR) {
        browser {
            testTask {
                enabled = false
            }
        }
        binaries.executable()
    }
    sourceSets {
        val commonMain by getting {
            dependencies {
                implementation(compose.runtime)
            }
        }
        val commonTest by getting {
            dependencies {
                implementation(kotlin("test"))
            }
        }
        val jvmMain by getting {
            dependencies {
                implementation("org.apache.commons:commons-compress:1.2")
            }
        }
        val jsMain by getting {
            dependencies {
                implementation(compose.web.core)
                implementation(npm("highlight.js", "11.7.0"))
                implementation(npm("file-saver", "2.0.5"))
                implementation(npm("jszip", "3.10.1"))
                implementation(npm("stream", "0.0.2"))
            }
        }
    }
}

task<Copy>("fixMissingResources") {
    dependsOn("jvmProcessResources")
    tasks.findByPath("jvmTest")?.dependsOn(this)

    from("$buildDir/processedResources/jvm/main")
    into("$buildDir/resources/")
}