Constraint modelling error: "check_belongs_to_model(::NonlinearExpression, ::Model)"

[Philippe1123]

Dear community,

I am trying to solve a stochastic optimal control problem where the goal is to minimize the total time.
The goal is thus to minimize the time where one of the constraints is that the computed value of an expected value must be below a certain threshold, i.e.,

$\text{min},t$

subjected to
$E[q\left(t\right)] \leq 0.9$
where $q\left(t\right) := \int_\Omega \text{e}^{-\int_0^{T_F} \gamma\left(x\left(\tau\right),\omega\right) d,\tau}\phi\left(\omega\right) d,\omega$

The $\gamma$ function is nonlinear, e.g.,

$\gamma\left(x\left(\tau\right),\omega\right):= x * \omega$

When I try to simulate this, I obtain the following error:

ERROR: LoadError: MethodError: no method matching check_belongs_to_model(::NonlinearExpression, ::Model)
Closest candidates are:
check_belongs_to_model(::ConstraintRef, ::AbstractModel) at ~/.julia/packages/JuMP/jZvaU/src/constraints.jl:63
check_belongs_to_model(::ScalarConstraint, ::Any) at ~/.julia/packages/JuMP/jZvaU/src/constraints.jl:607
check_belongs_to_model(::VectorConstraint, ::Any) at ~/.julia/packages/JuMP/jZvaU/src/constraints.jl:667

However if I implement it with a given maximum time and define the objective as a minimization problem of the expected value, i.e.,

$\text{min}, E[q\left(t\right)] $
subjected to some constraints

I do not get this error.

How can I solve this problem? Any help is greatly appreciated :)
Please find hereunder some example code where this error can be observed.

Example code for the first optimization problem (which gives the aforementioned error):

using Distributions
using InfiniteOpt
using Ipopt
using Distributions
model = InfiniteModel(Ipopt.Optimizer)
sup = 100
Ξ = [Uniform(5, 25), Uniform(5, 25)] 
@infinite_parameter(model, t in [0, 1.0], num_supports = sup)
@infinite_parameter(model, ξ[c in 1:2] ~ Ξ[c],num_supports = 400)
@variable(model, 1 <= tf <= 10, start = 1)
@variable(model, x >= 0, Infinite(t))
@variable(model, y >= 0, Infinite(t))
p = (x_n, y_n, ωx_n, ωy_n) -> x_n* y_n* ωx_n* ωy_n
@constraint(model,support_sum(-∫(p(x, y, ξ[1], ξ[2]) ,t),ξ)<=100)
@objective(model,Min,tf)
@constraint(model, 5 <= x <= 25)
@constraint(model, 5 <= y <= 25)
optimize!(model)

Example code for the second problem (which works):

using Distributions
using InfiniteOpt
using Ipopt
using Distributions   
model = InfiniteModel(Ipopt.Optimizer)
sup = 100
Ξ = [Uniform(5, 25), Uniform(5, 25)] 
@infinite_parameter(model, t in [0, 1.0], num_supports = sup)
@infinite_parameter(model, ξ[c in 1:2] ~ Ξ[c],num_supports = 400)
@variable(model, x >= 0, Infinite(t))
@variable(model, y >= 0, Infinite(t))
p = (x_n, y_n, ωx_n, ωy_n) -> x_n* y_n* ωx_n* ωy_n
@objective(model,Min,support_sum(-∫(p(x, y, ξ[1], ξ[2]) ,t),ξ))
@constraint(model, 5 <= x <= 25)
@constraint(model, 5 <= y <= 25)
optimize!(model)

[pulsipher]

Hi there and welcome!

You found a bug, thanks for sharing. It will be fixed by #318.

Also, note that your final time problem will not minimize the final time as you currently have it posed. To use the reformulation trick with tf you will need to reformulate the integral as a differential equation that is scaled by tf. Otherwise, as formulated the tf has no effect on the integral and can be trivially set to 1.

On a more minor note, you can and probably should move the variable bound constraints into @variable.

[Philippe1123]

Dear pulsipher,

Thanks alot!

Actually, the full problem I am considering is an optimal control one. So I have scaled these differential equations by the parameter tf. Do I also need to reformulate the integral and scale it then? If so, could you give me a pointer how to apply the reformulation of the integral?

[pulsipher]

On 2nd thought, I believe we can simply scale the integral by tf appropriately in this case:

using Distributions
using InfiniteOpt
using Ipopt

model = InfiniteModel(Ipopt.Optimizer)
Ξ = [Uniform(5, 25), Uniform(5, 25)] 
@infinite_parameter(model, s in [0, 1.0], num_supports = 100) # s = t / tf
@infinite_parameter(model, ξ[c in 1:2] ~ Ξ[c], num_supports = 400)

@variable(model, 1 <= tf <= 10, start = 1)
@variable(model, 5 <= x <= 25, Infinite(s))
@variable(model, 5 <= y <= 25, Infinite(s))

p = (x_n, y_n, ωx_n, ωy_n) -> x_n* y_n* ωx_n* ωy_n
@constraint(model, expect(exp(-tf * ∫(p(x, y, ξ[1], ξ[2]) , s)), ξ) <= 0.9)

@objective(model, Min, tf)

optimize!(model, check_support_data_dims = false)

opt_tf = value(tf)
opt_ts = value(s) * opt_tf
opt_y = value(y)
opt_x = value(x)

This will error until I make a new release of InfiniteOpt with the bug fix, but in the interim, you can use the following workaround:

using Distributions
using InfiniteOpt
using Ipopt

model = InfiniteModel(Ipopt.Optimizer)
Ξ = [Uniform(5, 25), Uniform(5, 25)] 
@infinite_parameter(model, s in [0, 1.0], num_supports = 100) # s = t / tf
@infinite_parameter(model, ξ[c in 1:2] ~ Ξ[c], num_supports = 400)

@variable(model, 1 <= tf <= 10, start = 1)
@variable(model, 5 <= x <= 25, Infinite(s))
@variable(model, 5 <= y <= 25, Infinite(s))

p = (x_n, y_n, ωx_n, ωy_n) -> x_n* y_n* ωx_n* ωy_n
@expression(model, myexpr, expect(exp(-tf * ∫(p(x, y, ξ[1], ξ[2]) , s)), ξ))
@constraint(model, convert(NLPExpr, myexpr) <= 0.9)

@objective(model, Min, tf)

optimize!(model, check_support_data_dims = false)

opt_tf = value(tf)
opt_ts = value(s) * opt_tf
opt_y = value(y)
opt_x = value(x)

Note that I modified the constraint to better match the formulation you gave. Currently, this gives a trivial solution, but I presume this is just a toy example.

[pulsipher]

As an update, v0.5.8 is now released. Updating InfiniteOpt will now resolve this bug.