build.gradle

apply plugin: 'eclipse'
apply plugin: 'java'
apply plugin: 'maven'
apply plugin: 'signing'

group = "org.peekmoon"
archivesBaseName = "database-walker"
version = "0.0.7"

sourceCompatibility = 1.8

repositories {
    mavenCentral()
}

task javadocJar(type: Jar) {
    classifier = 'javadoc'
    from javadoc
}

task sourcesJar(type: Jar) {
    classifier = 'sources'
    from sourceSets.main.allSource
}

artifacts {
    archives javadocJar, sourcesJar
}


dependencies {
    compile 'org.slf4j:slf4j-api:1.7.21'
    testCompile "junit:junit:4.11"
}

signing {
    sign configurations.archives
}


uploadArchives {
  repositories {
    mavenDeployer {
      beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }

      repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
        authentication(userName: ossrhUsername, password: ossrhPassword)
      }

      snapshotRepository(url: "https://oss.sonatype.org/content/repositories/snapshots/") {
        authentication(userName: ossrhUsername, password: ossrhPassword)
      }

      pom.project {
        name 'Database Walker'
        // packaging 'jar'
        description 'A module to select/insert/delete row and dependencies row in a database.'
        url 'https://github.com/arsou33/database-walker'
        
        scm {
          url 'https://github.com/arsou33/database-walker'
        }

        licenses {
          license {
            name 'The Apache License, Version 2.0'
            url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
          }
        }

        developers {
          developer {
            id 'arsouille'
            name 'Arsouille'
            email 'arsouille@peekmoon.org'
          }
        }
      }
    }
  }
}