nexusConfig.gradle

// Default parameters
if (!project.hasProperty("nexusUrl")) {
    ext.nexusUrl = "file:///tmp/sdkRepo"
}

if (!project.hasProperty("nexusUsername")) {
    ext.nexusUsername = ""
}

if (!project.hasProperty("nexusPassword")) {
    ext.nexusPassword = ""
}

ext.nexusRelease = "${nexusUrl}/service/local/staging/deploy/maven2/"
ext.nexusSnapshot = "${nexusUrl}/content/repositories/snapshots/"

private boolean signingConfigured() {
    return project.hasProperty("signing.keyId") && project.hasProperty("signing.password") \
      && project.hasProperty("signing.secretKeyRingFile")
}

allprojects {
    apply plugin: 'maven'
    if (signingConfigured()) {
        apply plugin: 'signing'
        signing {
            sign configurations.archives
        }
    }

    uploadArchives.repositories.mavenDeployer {
        if (signingConfigured()) {
            beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }
        }

        repository(url: nexusRelease) {
            authentication(userName: nexusUsername, password: nexusPassword)
        }

        snapshotRepository(url: nexusSnapshot) {
            authentication(userName: nexusUsername, password: nexusPassword)
        }
    }
}