build.gradle

import org.jetbrains.kotlin.gradle.tasks.KotlinCompile

plugins {
    id 'java'
    id 'org.springframework.boot' version '3.3.4'
    id 'io.spring.dependency-management' version '1.1.6'
    id 'org.jetbrains.kotlin.jvm' version '1.9.24'
    id 'org.jetbrains.kotlin.plugin.spring' version '1.9.24'
    id 'org.asciidoctor.jvm.convert' version '3.3.2'
    id 'com.google.protobuf' version '0.9.4'
    id 'com.google.cloud.tools.jib' version '3.4.0'
}

group 'testserver'
version '0.0.8'
description 'REST API Test'

java {
    sourceCompatibility = 21
    targetCompatibility = 21
}

repositories {
    mavenCentral()
}

configurations {
    compileOnly {
        extendsFrom annotationProcessor
    }
}

ext {
    // https://docs.spring.io/spring-boot/appendix/dependency-versions/coordinates.html
    set('snippetsDir', file("build/generated-snippets"))
}

dependencies {
    implementation platform('software.amazon.awssdk:bom:2.18.21')

    implementation 'org.springframework.boot:spring-boot-starter-aop'
    implementation 'org.springframework.boot:spring-boot-starter-webflux'
    implementation 'org.springframework.boot:spring-boot-starter-log4j2'
    modules {
        module("org.springframework.boot:spring-boot-starter-logging") {
            replacedBy("org.springframework.boot:spring-boot-starter-log4j2", "Use Log4j2 instead of Logback")
        }
    }
    implementation 'org.apache.logging.log4j:log4j-spring-boot'
    implementation 'org.springframework.boot:spring-boot-starter-actuator'

    implementation 'com.fasterxml.jackson.core:jackson-databind'
    implementation 'com.fasterxml.jackson.module:jackson-module-kotlin'
    implementation 'io.projectreactor.kotlin:reactor-kotlin-extensions'
    implementation 'org.jetbrains.kotlin:kotlin-stdlib'
    implementation 'org.jetbrains.kotlin:kotlin-reflect'
    implementation  'org.jetbrains.kotlinx:kotlinx-coroutines-core'
    implementation  'org.jetbrains.kotlinx:kotlinx-coroutines-reactive'
    implementation 'org.jetbrains.kotlinx:kotlinx-coroutines-reactor'

    compileOnly 'org.projectlombok:lombok'
    annotationProcessor 'org.projectlombok:lombok'
    annotationProcessor 'org.springframework.boot:spring-boot-configuration-processor'

    implementation 'software.amazon.awssdk:dynamodb'

    implementation 'com.google.protobuf:protobuf-java:4.28.2'

    testImplementation 'org.springframework.boot:spring-boot-starter-test'
    testImplementation 'io.projectreactor:reactor-test'
    testImplementation 'org.springframework.restdocs:spring-restdocs-webtestclient'
    testImplementation 'org.assertj:assertj-core'
    testImplementation 'app.cash.turbine:turbine:1.0.0'
    testCompileOnly 'org.projectlombok:lombok'
    testAnnotationProcessor 'org.projectlombok:lombok'
}

tasks.withType(KotlinCompile).configureEach {
    kotlinOptions {
        freeCompilerArgs = ['-Xjsr305=strict']
        jvmTarget = '21'
    }
}

protobuf {
    protoc {
        artifact = 'com.google.protobuf:protoc:4.28.2'
    }
}

tasks.named('test') {
    outputs.dir snippetsDir
    useJUnitPlatform()
}

tasks.named('asciidoctor') {
    inputs.dir snippetsDir
    dependsOn test
}

jib {
    from.image = 'openjdk:21-jdk-alpine'
    to.image = "${project.group}/${bootJar.archiveBaseName}"
    container {
        args = ['-Djava.security.egd=file:/dev/./urandom']
        ports = ['8080']
        format = 'OCI'
    }
}