build.gradle

ext.githubProjectName = rootProject.name // Change if github project name is not the same as the root project's name

buildscript {
    repositories {
        mavenLocal()
        mavenCentral() // maven { url 'http://jcenter.bintray.com' }
    }
    apply from: file('gradle/buildscript.gradle'), to: buildscript 
}

allprojects {
    repositories { 
        mavenCentral() // maven { url: 'http://jcenter.bintray.com' }
    }
}

apply from: file('gradle/convention.gradle')
apply from: file('gradle/maven.gradle')
//apply from: file('gradle/check.gradle')
//apply from: file('gradle/license.gradle') // Waiting for re-release
apply from: file('gradle/release.gradle')

apply plugin: 'idea'
apply plugin: 'eclipse'

subprojects {
    apply plugin: 'idea'
    apply plugin: 'eclipse'
    apply plugin: 'java'

    group = "com.netflix.${githubProjectName}" // TEMPLATE: Set to organization of project

    dependencies {
        testCompile 'org.testng:testng:6.1.1'
    }
}

project(':exhibitor-core') {
    dependencies {
        compile('org.apache.zookeeper:zookeeper:3.4.5') {
            exclude group: 'com.sun.jmx', module: 'jmxri'
            exclude group: 'com.sun.jdmk', module: 'jmxtools'
            exclude group: 'javax.jms', module: 'jms'

            // JLine pulls this in as a compile dependency, they have fixed it in future versions
            exclude group: 'junit', module: 'junit'
        }
        compile 'org.apache.curator:curator-framework:2.3.0'
        compile 'org.apache.curator:curator-recipes:2.3.0'
        compile 'com.netflix.servo:servo-core:0.5.2'
        compile 'com.google.guava:guava:11.0.1'
        compile 'javax.ws.rs:jsr311-api:1.1.1'
        compile 'org.codehaus.jackson:jackson-mapper-asl:1.8.3'
        compile 'org.apache.lucene:lucene-core:3.6.0'
        compile 'com.sun.jersey:jersey-client:1.11'

        // if you are using Java 7 you can remove this and switch to the JDK version
        compile 'org.codehaus.jsr166-mirror:jsr166y:1.7.0'

        compile 'com.amazonaws:aws-java-sdk:1.3.22'   // should be provided - gradle doesn't support
        compile 'com.sun.jersey:jersey-bundle:1.9.1'  // should be provided - gradle doesn't support
        compile 'com.sun.xml.bind:jaxb-impl:2.2.4'   // should be provided - gradle doesn't support

        testCompile 'org.apache.curator:curator-test:2.3.0'
        testCompile 'org.mortbay.jetty:jetty:6.1.22'
        testCompile 'org.mockito:mockito-core:1.8.5'
    }

    jar {
        manifest {
            attributes (
                'Implementation-Title': 'exhibitor-core',
                'Implementation-Version': project.version
            )
        }
    }
}

project(':exhibitor-standalone') {
    dependencies {
        compile (project(":exhibitor-core")) {
            exclude group: 'com.sun.jersey', module: 'jersey-client'
        }
        compile 'com.sun.jersey:jersey-bundle:1.9.1'
        compile 'com.sun.xml.bind:jaxb-impl:2.2.4'
        compile 'javax.servlet:servlet-api:2.5'    // should be provided - gradle doesn't support
        compile 'org.mortbay.jetty:jetty:6.1.22'
        compile 'com.google.guava:guava:11.0.1'
        compile 'commons-cli:commons-cli:1.2'
        compile 'com.amazonaws:aws-java-sdk:1.3.22'
        compile 'org.slf4j:slf4j-log4j12:1.7.0'
    }
}