build.gradle

apply plugin: "java-library"
apply plugin: 'maven-publish'

version '2.22.8'

sourceCompatibility = 1.8
targetCompatibility = 1.8

repositories {
    mavenCentral()
    maven { url "https://jitpack.io" }
}

test {
    useJUnitPlatform()

    testLogging {
        events "passed", "skipped", "failed", "standardError"
    }
}

tasks.withType(JavaCompile) {
    options.encoding = 'UTF-8'
}

tasks.withType(Test) {
	systemProperty "file.encoding", "UTF-8"
}

dependencies {
    implementation "com.github.esotericsoftware:jsonbeans:c3520fcc51" // = 0.10
    api "com.esotericsoftware:kryo:5.5.0"

    testImplementation "org.junit.jupiter:junit-jupiter-api:5.9.2"
    testRuntimeOnly "org.junit.jupiter:junit-jupiter-engine:5.9.2"
}

task sourcesJar(type: Jar, dependsOn: classes) {
    archiveClassifier = 'sources'
    from sourceSets.main.allSource
}

task javadocJar(type: Jar, dependsOn: javadoc) {
    archiveClassifier = 'javadoc'
    from javadoc.destinationDir
}

javadoc {
    options {
        addBooleanOption('author', true)
        links "https://docs.oracle.com/en/java/javase/17/docs/api/"
    }
}

publishing {
    publications {
        plugin(MavenPublication) { publication ->
            groupId 'com.github.crykn'
            artifactId project.archivesBaseName
            version project.version

            from components['java']

            artifact sourcesJar
            artifact javadocJar
        }
    }

    repositories {
        mavenLocal()
    }
}