-
Notifications
You must be signed in to change notification settings - Fork 7
/
pophint.el
1579 lines (1412 loc) · 71.2 KB
/
pophint.el
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
;;; pophint.el --- Provide navigation using pop-up tips, like Firefox's Vimperator Hint Mode
;; Copyright (C) 2013 Hiroaki Otsu
;; Author: Hiroaki Otsu <[email protected]>
;; Keywords: popup
;; URL: https://github.com/aki2o/emacs-pophint
;; Version: 1.4.0
;; Package-Requires: ((log4e "0.4.0") (yaxception "1.0.0"))
;; This program is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
;; This file is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;; GNU General Public License for more details.
;; You should have received a copy of the GNU General Public License
;; along with this program. If not, see <http://www.gnu.org/licenses/>.
;;; Commentary:
;;
;; This extension provides navigation like the Vimperator Hint Mode of Firefox.
;; The interface has the following flow.
;; 1. pop-up tip about the matched point for some action which user want.
;; 2. do some action for the user selecting.
;;
;; For detail, see <https://github.com/aki2o/emacs-pophint/blob/master/README.md>
;; For configuration, see Configuration section in <https://github.com/aki2o/emacs-pophint/wiki>
;;
;; Enjoy!!!
;;; Code:
(require 'cl-lib)
(require 'rx)
(require 'mode-local)
(require 'yaxception)
(require 'log4e)
(require 'pos-tip nil t)
(defgroup pophint nil
"Pop-up the hint tip of candidates for doing something"
:group 'popup
:prefix "pophint:")
(defcustom pophint:popup-chars "hjklyuiopnm"
"Characters for pop-up hint."
:type 'string
:group 'pophint)
(defcustom pophint:select-source-chars "123456789"
"Characters for selecting source."
:type 'string
:group 'pophint)
(defcustom pophint:select-source-method 'use-source-char
"Method to select source.
This value is one of the following symbols.
- use-source-char
Push the key bound to each of sources from `pophint:select-source-chars'
without pushing `pophint:switch-source-char'.
- use-popup-char
Push the key bound to each of sources from `pophint:popup-chars'
after pushing `pophint:switch-source-char'.
- nil
Push `pophint:switch-source-char' only."
:type '(choice (const use-source-char)
(const use-popup-char)
(const nil))
:group 'pophint)
(defcustom pophint:switch-source-char "s"
"Character for switching source used to pop-up."
:type 'string
:group 'pophint)
(defcustom pophint:switch-source-reverse-char "S"
"Character for switching source used to pop-up in reverse."
:type 'string
:group 'pophint)
(defcustom pophint:switch-source-delay 0.5
"Second for delay to switch source used to pop-up.
If nil, it means not delay."
:type 'number
:group 'pophint)
(defcustom pophint:switch-source-selectors nil
"List of dedicated selector for source.
Example:
\\='((\"Quoted\" . \"q\")
(\"Url/Path\" . \"u\"))
"
:type '(repeat (cons string string))
:group 'pophint)
(defcustom pophint:switch-direction-char "d"
"Character for switching direction of pop-up."
:type 'string
:group 'pophint)
(defcustom pophint:switch-direction-reverse-char "D"
"Character for switching direction of pop-up in reverse."
:type 'string
:group 'pophint)
(defcustom pophint:switch-window-char "w"
"Character for switching window of pop-up."
:type 'string
:group 'pophint)
(defcustom pophint:popup-max-tips 200
"Maximum counts of pop-up hint.
If nil, it means limitless."
:type 'integer
:group 'pophint)
(defcustom pophint:default-require-length 3
"Default minimum length of matched text for pop-up."
:type 'integer
:group 'pophint)
(defcustom pophint:switch-direction-p t
"Whether switch direction of pop-up."
:type 'boolean
:group 'pophint)
(defcustom pophint:do-allwindow-p nil
"Whether do pop-up at all windows."
:type 'boolean
:group 'pophint)
(defcustom pophint:use-pos-tip nil
"Whether use pos-tip.el to show prompt."
:type 'boolean
:group 'pophint)
(defcustom pophint:inch-forward-length 3
"Size of chars to make next hint by `'"
:type 'integer
:group 'pophint)
(make-obsolete 'pophint-config:inch-length 'pophint:inch-forward-length "1.1.0")
(defface pophint:tip-face
'((t (:background "khaki1" :foreground "black" :bold t)))
"Face for the pop-up hint."
:group 'pophint)
(defface pophint:match-face
'((t (:background "steel blue" :foreground "white")))
"Face for matched hint text."
:group 'pophint)
(defface pophint:pos-tip-face
'((((class color) (background dark)) (:background "ivory" :foreground "black"))
(((class color) (background light)) (:background "gray10" :foreground "white"))
(t (:background "ivory" :foreground "black")))
"Face for the tip of pos-tip.el"
:group 'pophint)
(defface pophint:prompt-bind-part-face
'((t (:inherit font-lock-keyword-face :bold t)))
"Face for the part of bound key in prompt."
:group 'pophint)
(defface pophint:prompt-active-part-face
'((t (:bold t)))
"Face for the part of active source/direction in prompt."
:group 'pophint)
(defvar pophint:sources nil
"Buffer local sources for pop-up hint tip flexibly.")
(make-variable-buffer-local 'pophint:sources)
(defvar pophint:global-sources nil
"Global sources for pop-up hint tip flexibly")
(defvar pophint:dedicated-sources nil
"Dedicated sources for pop-up hint tip in particular situation.")
(cl-defstruct pophint:hint window popup overlay (startpt 0) (endpt 0) (value ""))
(cl-defstruct pophint:action name action)
(log4e:deflogger "pophint" "%t [%l] %m" "%H:%M:%S" '((fatal . "fatal")
(error . "error")
(warn . "warn")
(info . "info")
(debug . "debug")
(trace . "trace")))
(pophint--log-set-level 'trace)
(cl-defstruct pophint--condition
source sources action action-name direction window allwindow use-pos-tip
not-highlight not-switch-direction not-switch-window not-switch-source
tip-face)
(defvar pophint--action-hash (make-hash-table :test 'equal))
(defvar pophint--enable-allwindow-p nil)
(defvar pophint--disable-allwindow-p nil)
(defvar pophint--last-hints nil)
(defvar pophint--last-condition nil)
(defvar pophint--last-context-condition-hash (make-hash-table :test 'equal))
(defvar pophint--current-context nil)
(defvar pophint--current-window nil)
(defvar pophint--current-point nil)
(defvar pophint--resumed-input-method nil)
(defvar pophint--non-alphabet-chars "!\"#$%&'()-=^~\\|@`[{;+:*]},<.>/?_")
(defvar pophint--default-search-regexp
(let ((min-len pophint:default-require-length))
(rx-to-string `(and point (or
;; 連続する空白
(and (group-n 1 (>= ,min-len blank)))
;; 連続する記号
(and (* blank)
(group-n 1 (>= ,min-len (any ,pophint--non-alphabet-chars))))
;; 連続する英数字
(and (* (any ,pophint--non-alphabet-chars blank))
(group-n 1 (>= ,min-len (any "a-zA-Z0-9"))))
;; ;; 単語
;; (and (** 1 ,(1- min-len) (not word))
;; (group-n 1 (>= ,min-len word)))
;; ;; 単語区切りまでの何か
;; (and (group-n 1 (** ,min-len ,min-len not-newline) (*? not-newline))
;; word-boundary)
;; 改行
(and (* (any ,pophint--non-alphabet-chars blank))
;;(and (*? not-newline)
(group-n 1 "\n"))
)))))
(defun pophint--default-search ()
(if (re-search-forward pophint--default-search-regexp nil t)
`(:startpt ,(match-beginning 1) :endpt ,(match-end 1) :value ,(match-string-no-properties 1))
(let ((startpt (point))
(endpt (progn (forward-word) (point))))
(when (> endpt startpt)
`(:startpt ,startpt :endpt ,endpt :value ,(buffer-substring-no-properties startpt endpt))))))
(defvar pophint--default-source '((shown . "Default")
(requires . 1)
(method . pophint--default-search)
(highlight . nil)))
(defvar pophint--default-action (lambda (hint)
(let ((wnd (pophint:hint-window hint)))
(push-mark)
(when (and (windowp wnd)
(window-live-p wnd)
(not (eq (selected-window) wnd)))
(select-window wnd))
(goto-char (pophint:hint-startpt hint)))))
(defvar pophint--default-action-name "Go/SrcAct")
(defvar pophint--next-window-source
'((shown . "Wnd")
(requires . 0)
(highlight . nil)
(tip-face-attr . (:height 2.0))
(init . (lambda ()
(setq pophint--current-point (point))))
(method . (lambda ()
(cond ((eq pophint--current-window (selected-window))
(setq pophint--current-window nil))
((and (window-minibuffer-p (selected-window))
(not (minibuffer-window-active-p (selected-window))))
(setq pophint--current-window nil))
(t
(setq pophint--current-window (selected-window))
(when (= (buffer-size) 0) (insert " "))
(let* ((startpt (min (save-excursion
(goto-char (window-start))
(forward-line 1)
(while (and (< (- (pos-eol) (point)) (window-hscroll))
(< (point) (point-max)))
(forward-line 1))
(+ (point) (window-hscroll)))
(1- (point-max))))
(endpt (max pophint--current-point (1+ startpt))))
`(:startpt ,startpt :endpt ,endpt :value ""))))))
(action . hint)))
;;;;;;;;;;;;;
;; Utility
(cl-defmacro pophint--aif (test then &rest else)
(declare (indent 2))
`(let ((it ,test)) (if it ,then ,@else)))
(cl-defmacro pophint--awhen (test &rest body)
(declare (indent 1))
`(let ((it ,test)) (when it ,@body)))
(cl-defun pophint--show-message (msg &rest args)
(apply 'message (concat "[PopHint] " msg) args)
nil)
(defsubst pophint--current-not-highlight-p (cond)
(or (pophint--condition-not-highlight cond)
(pophint--awhen (assq 'highlight (pophint--condition-source cond))
(not (cdr-safe it)))))
(defsubst pophint--current-not-switch-source-p (cond)
(or (pophint--condition-not-switch-source cond)
(< (length (pophint--condition-sources cond)) 2)))
(defsubst pophint--current-action (cond)
(or (pophint--condition-action cond)
(assoc-default 'action (pophint--condition-source cond))
pophint--default-action))
(defvar pophint--stocked-overlays nil)
(defsubst pophint--make-overlay (start end)
(or (pophint--awhen (pop pophint--stocked-overlays)
(move-overlay it start end (current-buffer)))
(make-overlay start end (current-buffer))))
(defsubst pophint--stock-overlay (ov)
(overlay-put ov 'text nil)
(overlay-put ov 'window nil)
(overlay-put ov 'display nil)
(overlay-put ov 'after-string nil)
(overlay-put ov 'face nil)
(overlay-put ov 'priority nil)
(push ov pophint--stocked-overlays))
(defsubst pophint--delete (hint)
(when (pophint:hint-p hint)
(let* ((tip (pophint:hint-popup hint))
(ov (pophint:hint-overlay hint)))
(when ov
;; (delete-overlay ov)
(pophint--stock-overlay ov)
(setf (pophint:hint-overlay hint) nil))
(when tip
;; (delete-overlay tip)
(pophint--stock-overlay tip)
(setf (pophint:hint-popup hint) nil))
nil)))
(defun pophint--deletes (hints)
(pophint--trace "start delete hints. hints:[%s]" (length hints))
(dolist (hint hints)
(pophint--delete hint))
nil)
(defun pophint--compile-to-function (something)
(cond ((functionp something)
something)
((and (symbolp something)
(boundp something))
(symbol-value something))
((listp something)
something)
(t
nil)))
(defsubst pophint--compile-source (source)
(cond ((symbolp source)
(symbol-value source))
((listp source)
source)))
(defun pophint--compile-sources (sources)
(cl-loop for s in sources
collect (pophint--compile-source s)))
(make-face 'pophint--tip-face-temp)
(defsubst pophint--update-tip-face (face-attr)
(if (not face-attr)
'pophint:tip-face
(copy-face 'pophint:tip-face 'pophint--tip-face-temp)
(apply 'set-face-attribute 'pophint--tip-face-temp nil face-attr)
'pophint--tip-face-temp))
(defsubst pophint--make-index-char-string (idx char-list)
(if (or (not (stringp char-list))
(string= char-list ""))
""
(let* ((basei (length char-list)))
(cl-loop with ret = ""
with n = idx
for i = (/ n basei)
for r = (- n (* basei i))
until (= i 0)
do (setq n i)
do (setq ret (concat (substring char-list r (+ r 1)) ret))
finally return (concat (substring char-list r (+ r 1)) ret)))))
(defsubst pophint--make-unique-char-strings (count char-list &optional not-upcase exclude-strings)
(cl-loop with reth = (make-hash-table :test 'equal)
with idx = 0
with currcount = 0
while (< currcount count)
for currstr = (pophint--make-index-char-string idx char-list)
for currstr = (if not-upcase currstr (upcase currstr))
do (cl-incf idx)
do (when (not (member currstr exclude-strings))
(puthash currstr t reth)
(cl-incf currcount))
do (let ((chkvalue (substring currstr 0 (- (length currstr) 1))))
(when (gethash chkvalue reth)
(remhash chkvalue reth)
(cl-decf currcount)))
finally return (cl-loop for k being the hash-keys in reth collect k)))
(defun pophint--set-selector-sources (sources)
(cl-loop with char-list = (cl-case pophint:select-source-method
(use-popup-char pophint:popup-chars)
(use-source-char pophint:select-source-chars)
(t nil))
with excludes = (cl-loop for src in sources
for s = (assoc-default (assoc-default 'shown src) pophint:switch-source-selectors)
if s
append (cl-loop with idx = (length s)
while (> idx 0)
collect (substring s 0 idx)
do (cl-decf idx)))
with selectors = (when char-list
(pophint--make-unique-char-strings (length sources) char-list t excludes))
for src in sources
for selector = (or (assoc-default (assoc-default 'shown src) pophint:switch-source-selectors)
(when selectors (pop selectors)))
do (pophint--awhen (assq 'selector src)
(setq src (delq it src)))
if selector
do (add-to-list 'src `(selector . ,selector) t)
collect src))
(defun pophint--get-available-sources (window)
(let* ((sources (with-current-buffer (or (and (windowp window)
(window-live-p window)
(window-buffer window))
(current-buffer))
(pophint--compile-sources pophint:sources))))
(cl-loop for src in (pophint--compile-sources pophint:global-sources)
do (add-to-list 'sources src t))
;; (add-to-list 'sources pophint--default-source t)
sources))
(cl-defun pophint--set-last-condition (condition &key context)
(pophint--debug "set last condition of %s\n%s" context condition)
(setq pophint--last-condition condition)
(when context
(puthash context condition pophint--last-context-condition-hash)))
(defun pophint--get-last-condition-with-context (context)
(gethash context pophint--last-context-condition-hash))
(cl-defmacro pophint--with-no-last-condition (&rest body)
(declare (indent 0))
`(let ((pophint--last-condition nil)
(pophint--last-context-condition-hash (make-hash-table :test 'equal)))
,@body))
(defvar pophint--selected-action nil)
(defvar pophint--selected-hint nil)
(defun pophint--do-action (hint action)
(when (pophint:hint-p hint)
(let* ((tip (pophint:hint-popup hint))
(selected (pophint:hint-value hint)))
(pophint--debug "start action. selected:[%s] action:%s" selected action)
(pophint--delete hint)
(cond ((eq action 'value)
(pophint:hint-value hint))
((eq action 'point)
(pophint:hint-startpt hint))
((eq action 'hint)
hint)
((functionp action)
(setq pophint--selected-action action)
(setq pophint--selected-hint hint)
(run-at-time 0 nil (lambda ()
(let ((action pophint--selected-action)
(hint pophint--selected-hint))
(setq pophint--selected-action nil)
(setq pophint--selected-hint nil)
(funcall action hint)))))
(t
(error "Unsupported action"))))))
(cl-defmacro pophint--maybe-kind-mode-buffer-p (buf &rest modes)
(declare (indent 0))
`(let ((buf-mode (buffer-local-value 'major-mode ,buf)))
(when (or (memq buf-mode (list ,@modes))
(memq (get-mode-local-parent buf-mode) (list ,@modes)))
t)))
;;;;;;;;;;;;;;;;;;;;;
;; For Interactive
(defun pophint--menu-read-key-sequence (prompt use-pos-tip &optional timeout)
(pophint--trace "start menu read key sequence. prompt[%s] use-pos-tip[%s] timeout[%s]"
prompt use-pos-tip timeout)
;; Coding by referring to popup-menu-read-key-sequence
(catch 'timeout
(let ((timer (and timeout
(run-with-timer timeout nil
(lambda ()
(if (zerop (length (this-command-keys)))
(throw 'timeout nil))))))
(old-global-map (current-global-map))
(temp-global-map (make-sparse-keymap))
(overriding-terminal-local-map (make-sparse-keymap)))
(substitute-key-definition 'keyboard-quit 'keyboard-quit temp-global-map old-global-map)
(define-key temp-global-map [menu-bar] (lookup-key old-global-map [menu-bar]))
(define-key temp-global-map [tool-bar] (lookup-key old-global-map [tool-bar]))
(when (current-local-map)
(define-key overriding-terminal-local-map [menu-bar] (lookup-key (current-local-map) [menu-bar])))
(yaxception:$
(yaxception:try
(use-global-map temp-global-map)
(clear-this-command-keys)
(if (and use-pos-tip
window-system
(featurep 'pos-tip))
(progn (pophint--pos-tip-show prompt)
(read-key-sequence nil))
(with-temp-message prompt
(read-key-sequence nil))))
(yaxception:finally
(use-global-map old-global-map)
(when timer (cancel-timer timer))
(when (and use-pos-tip
(featurep 'pos-tip))
(pos-tip-hide)))))))
(cl-defun pophint--make-source-selection-prompt (sources &key
(delimiter "|")
highlight-source)
(let ((hsrcnm (or (assoc-default 'shown highlight-source)
"")))
(mapconcat (lambda (src)
(let* ((srcnm (or (assoc-default 'shown src) "*None*"))
(selector (assoc-default 'selector src)))
(concat (if selector
(concat (propertize selector 'face 'pophint:prompt-bind-part-face) ":")
"")
(if (string= hsrcnm srcnm)
(propertize srcnm 'face 'pophint:prompt-active-part-face)
srcnm))))
sources
delimiter)))
(defun pophint--make-prompt (cond hint-count)
(let* ((source (pophint--condition-source cond))
(sources (pophint--condition-sources cond))
(actdesc (pophint--condition-action-name cond))
(direction (pophint--condition-direction cond))
(not-switch-direction (pophint--condition-not-switch-direction cond))
(not-switch-window (pophint--condition-not-switch-window cond))
(not-switch-source (pophint--current-not-switch-source-p cond))
(swsrctext (cond ((not not-switch-source)
(format "%s%s:SwSrc(%s) "
(propertize pophint:switch-source-char 'face 'pophint:prompt-bind-part-face)
(if pophint:switch-source-reverse-char
(concat "/"
(propertize pophint:switch-source-reverse-char 'face 'pophint:prompt-bind-part-face))
"")
(pophint--make-source-selection-prompt sources
:highlight-source source)))
((cl-loop for s in (append (list source) sources)
always (assoc-default 'dedicated s))
"")
(t
(format "Src[%s] " (or (assoc-default 'shown source)
"*None*")))))
(swdirtext (cond ((not not-switch-direction)
(format "%s%s:SwDrct(%s) "
(propertize pophint:switch-direction-char 'face 'pophint:prompt-bind-part-face)
(if pophint:switch-direction-reverse-char
(concat "/"
(propertize pophint:switch-direction-reverse-char 'face 'pophint:prompt-bind-part-face))
"")
(mapconcat (lambda (d)
(let* ((s (format "%s" d)))
(if (eq d direction)
(propertize s 'face 'pophint:prompt-active-part-face)
s)))
'(around forward backward)
"|")))
(t
"")))
(swwndtext (cond ((not not-switch-window)
(format "%s:SwWnd "
(propertize pophint:switch-window-char 'face 'pophint:prompt-bind-part-face)))
(t
""))))
(format "Select ch. Hints[%s] Act[%s] %s%s%s" hint-count actdesc swsrctext swdirtext swwndtext)))
(defun pophint--make-prompt-interactively ()
(let* ((count 1)
(acttext (cl-loop with ret = ""
for k being the hash-keys in pophint--action-hash using (hash-values act)
for desc = (pophint:action-name act)
do (cl-incf count)
do (setq ret (concat ret
(format "%s:%s "
(propertize k 'face 'pophint:prompt-bind-part-face)
desc)))
finally return ret))
(defact (propertize "<RET>" 'face 'pophint:prompt-bind-part-face)))
(format "Select ch. Actions[%s] %s:Default %s" count defact acttext)))
;;;;;;;;;;;;;;;;;
;; Pop-up Hint
(cl-defun pophint--let-user-select (cond &key context)
(when (not (pophint--condition-source cond))
(let ((sources (pophint--condition-sources cond)))
(setf (pophint--condition-source cond)
(or (and (> (length sources) 0) (nth 0 sources))
pophint--default-source))))
(let ((pophint--current-context (or context pophint--current-context this-command))
(hints (pophint--get-hints cond))
(tip-face-attr (assoc-default 'tip-face-attr (pophint--condition-source cond))))
(pophint--set-last-condition cond :context pophint--current-context)
(pophint--show-hint-tips hints
(pophint--current-not-highlight-p cond)
(or (pophint--condition-tip-face cond)
(pophint--update-tip-face tip-face-attr)))
(pophint--event-loop hints cond)))
(defsubst pophint--get-max-tips (source direction)
(let ((ret (or (assoc-default 'limit source)
pophint:popup-max-tips)))
(when (and (eq direction 'around)
ret)
(setq ret (/ ret 2)))
ret))
(defsubst pophint--get-hint-regexp (source)
(let ((re (or (assoc-default 'regexp source)
pophint--default-search-regexp)))
(cond ((stringp re) re)
((boundp re) (symbol-value re))
((functionp re) (funcall re))
(t (eval re)))))
(defsubst pophint--get-search-function (srcmtd direction)
(cond ((functionp srcmtd)
srcmtd)
((and (listp srcmtd)
(> (length srcmtd) 0))
(nth 0 srcmtd))))
(defsubst pophint--valid-location-p (lastpt startpt endpt)
(when (and startpt endpt
(> startpt lastpt)
(> endpt startpt))
t))
(defsubst pophint--hintable-location-p (direction currpt startpt endpt)
(when (and (not (ignore-errors (invisible-p startpt)))
(not (ignore-errors (invisible-p (1- endpt))))
(cl-case direction
(around t)
(forward (>= startpt currpt))
(backward (< endpt currpt))))
t))
(cl-defun pophint--get-hints (cond)
(let* ((source (pophint--condition-source cond))
(direction (pophint--condition-direction cond))
(window (pophint--condition-window cond))
(allwindow (pophint--condition-allwindow cond))
(wndchker (pophint--compile-to-function (assoc-default 'activebufferp source)))
(init (pophint--compile-to-function (assoc-default 'init source)))
(requires (or (assoc-default 'requires source)
pophint:default-require-length))
(re (pophint--get-hint-regexp source))
(srcmtd (pophint--compile-to-function (assoc-default 'method source)))
(srchfnc (pophint--get-search-function srcmtd direction))
(maxtips (pophint--get-max-tips source direction))
forward-hints backward-hints)
(dolist (wnd (or (when allwindow (window-list nil t))
(and (windowp window) (window-live-p window) (list window))
(list (nth 0 (get-buffer-window-list)))))
(with-selected-window wnd
(when (or (not (functionp wndchker))
(funcall wndchker (window-buffer)))
(save-restriction
(yaxception:$
(yaxception:try (narrow-to-region
(if (eq direction 'forward) (point) (window-start))
(if (eq direction 'backward) (point) (window-end))))
(yaxception:catch 'error e
(pophint--warn "failed narrow region : window:%s startpt:%s endpt:%s" wnd (window-start) (window-end))))
(save-excursion
(cl-loop initially (progn
(pophint--trace
"start searching hint. require:[%s] max:[%s] buffer:[%s] point:[%s]\nregexp: %s\nfunc: %s"
requires maxtips (current-buffer) (point) re srchfnc)
(when (functionp init) (funcall init))
(goto-char (point-min)))
with currpt = (point)
with lastpt = 0
with cnt = 0
with mtdret
while (and (yaxception:$
(yaxception:try
(cond (srchfnc (setq mtdret (funcall srchfnc)))
(t (re-search-forward re nil t))))
(yaxception:catch 'error e
(pophint--error "failed seek next popup point : %s\n%s"
(yaxception:get-text e) (yaxception:get-stack-trace-string e))))
(or (not maxtips)
(< cnt maxtips)))
for startpt = (cond ((pophint:hint-p mtdret) (pophint:hint-startpt mtdret))
(mtdret (plist-get mtdret :startpt))
(t (or (match-beginning 1) (match-beginning 0))))
for endpt = (cond ((pophint:hint-p mtdret) (pophint:hint-endpt mtdret))
(mtdret (plist-get mtdret :endpt))
(t (or (match-end 1) (match-end 0))))
for value = (cond ((pophint:hint-p mtdret) (pophint:hint-value mtdret))
(mtdret (plist-get mtdret :value))
((match-beginning 1) (match-string-no-properties 1))
(t (match-string-no-properties 0)))
if (not (pophint--valid-location-p lastpt startpt endpt))
return (pophint--warn "found hint location is invalid. text:[%s] lastpt:[%s] startpt:[%s] endpt:[%s]"
value lastpt startpt endpt)
if (and (>= (length value) requires)
(pophint--hintable-location-p direction currpt startpt endpt))
do (let ((hint (cond ((pophint:hint-p mtdret) mtdret)
(t (make-pophint:hint :startpt startpt :endpt endpt :value value)))))
(pophint--trace "found hint. text:[%s] startpt:[%s] endpt:[%s]" value startpt endpt)
(setf (pophint:hint-window hint) (selected-window))
(cl-incf cnt)
(if (<= endpt currpt)
(setq backward-hints (append (list hint) backward-hints))
(setq forward-hints (append forward-hints (list hint)))))
do (setq lastpt startpt)))))))
(append forward-hints backward-hints)))
(make-face 'pophint--minibuf-tip-face)
(defun pophint--show-hint-tips (hints not-highlight &optional tip-face)
(pophint--trace "start show hint tips. count:[%s] not-highlight:[%s] tip-face:[%s]"
(length hints) not-highlight tip-face)
(pophint:delete-last-hints)
(yaxception:$
(yaxception:try
(cl-loop initially (progn
(copy-face (or tip-face 'pophint:tip-face) 'pophint--minibuf-tip-face)
(set-face-attribute 'pophint--minibuf-tip-face nil :height 1.0))
with orgwnd = (selected-window)
with wnd = orgwnd
with tiptexts = (pophint--make-unique-char-strings (length hints) pophint:popup-chars)
with minibufp = (window-minibuffer-p wnd)
for hint in hints
for tiptext = (or (when tiptexts (pop tiptexts)) "")
for nextwnd = (pophint:hint-window hint)
if (string= tiptext "")
return nil
if (not (eq wnd nextwnd))
do (progn (select-window nextwnd t)
(setq wnd (selected-window))
(setq minibufp (window-minibuffer-p wnd)))
do (let* ((startpt (pophint:hint-startpt hint))
(endpt (pophint:hint-endpt hint))
;; Get a covered part by the pop-up tip
(covered-endpt (+ startpt (length tiptext)))
(covered-v (buffer-substring-no-properties startpt (min covered-endpt (point-max))))
;; The range, which the pop-up tip covers, is shrinked if it includes linefeed
(tip-endpt (+ startpt (or (string-match "\n" covered-v)
(length tiptext))))
(tip-len (- tip-endpt startpt))
(tip (pophint--make-overlay startpt tip-endpt))
(ov (when (not not-highlight)
(pophint--make-overlay startpt endpt)))
(tip-face (or (when minibufp 'pophint--minibuf-tip-face)
tip-face
'pophint:tip-face)))
(put-text-property 0 (length tiptext) 'face tip-face tiptext)
(overlay-put tip 'text tiptext)
(overlay-put tip 'window (selected-window))
(overlay-put tip 'display (substring tiptext 0 tip-len))
(overlay-put tip 'after-string (substring tiptext tip-len))
(overlay-put tip 'priority 99)
(setf (pophint:hint-popup hint) tip)
(when ov
(overlay-put ov 'window (selected-window))
(overlay-put ov 'face 'pophint:match-face)
(overlay-put ov 'priority 10)
(setf (pophint:hint-overlay hint) ov)))
finally do (select-window orgwnd t)))
(yaxception:catch 'error e
(pophint--deletes hints)
(pophint--error "failed show hint tips : %s\n%s" (yaxception:get-text e) (yaxception:get-stack-trace-string e))
(yaxception:throw e))))
(defsubst pophint--get-next-source (source sources &optional reverse)
(cl-loop with maxidx = (- (length sources) 1)
with i = (if reverse maxidx 0)
with endi = (if reverse 0 maxidx)
while (not (= i endi))
for currsrc = (nth i sources)
if (equal source currsrc)
return (let* ((nidx (if reverse (- i 1) (+ i 1)))
(nidx (cond ((< nidx 0) maxidx)
((> nidx maxidx) 0)
(t nidx))))
(pophint--trace "got next source index : %s" nidx)
(nth nidx sources))
do (if reverse (cl-decf i) (cl-incf i))
finally return (let ((nidx (if reverse maxidx 0)))
(nth nidx sources))))
(defsubst pophint--get-next-window (window)
(pophint--with-no-last-condition
(let ((basic-getter (lambda (w)
(with-selected-window (or (and (windowp w) (window-live-p w) w)
(get-buffer-window))
(next-window)))))
(if (<= (length (window-list)) 2)
(funcall basic-getter window)
(or (pophint--awhen (pophint:do :source pophint--next-window-source :allwindow t :use-pos-tip t)
(pophint:hint-window it))
(progn
(pophint--warn "failed get next window by pophint:do")
(funcall basic-getter window)))))))
(cl-defun pophint--event-loop (hints cond &optional (inputed "") source-selection)
(yaxception:$
(yaxception:try
(if (and (= (length hints) 1)
(not (string= inputed "")))
(pop hints)
(setq pophint--last-hints hints)
(let* ((source (pophint--condition-source cond))
(sources (pophint--condition-sources cond))
(action-name (pophint--condition-action-name cond))
(window (pophint--condition-window cond))
(allwindow (pophint--condition-allwindow cond))
(not-switch-direction (pophint--condition-not-switch-direction cond))
(not-switch-window (pophint--condition-not-switch-window cond))
(not-switch-source (pophint--current-not-switch-source-p cond))
(key (pophint--menu-read-key-sequence (pophint--make-prompt cond (length hints))
(pophint--condition-use-pos-tip cond)))
(gbinding (when key (lookup-key (current-global-map) key)))
(binding (or (when (and key (current-local-map))
(lookup-key (current-local-map) key))
gbinding)))
(pophint--trace "got user input. key:[%s] gbinding:[%s] binding:[%s]" key gbinding binding)
;; Case by user input
(cond
;; Error
((or (null key) (zerop (length key)))
(pophint--warn "can't get user input")
(pophint--deletes hints))
;; Quit
((eq gbinding 'keyboard-quit)
(pophint--debug "user inputed keyboard-quit")
(pophint--deletes hints)
(keyboard-quit)
nil)
;; Restart loop
((or (eq gbinding 'backward-delete-char-untabify)
(eq gbinding 'delete-backward-char))
(pophint--debug "user inputed delete command")
(pophint--deletes hints)
(pophint--let-user-select cond))
((or (eq gbinding 'self-insert-command)
(and (stringp key)
(string-match key (mapconcat (lambda (s) (or s ""))
(list pophint:popup-chars
pophint:select-source-chars
pophint:switch-source-char
pophint:switch-source-reverse-char
pophint:switch-direction-char
pophint:switch-direction-reverse-char
pophint:switch-window-char)
""))))
(cond
;; Grep hints
((and (string-match key pophint:popup-chars)
(not source-selection))
(pophint--debug "user inputed hint char")
(let* ((currinputed (concat inputed (upcase key)))
(nhints (cl-loop with re = (concat "\\`" currinputed)
for hint in hints
for tip = (pophint:hint-popup hint)
for tiptext = (or (when (overlayp tip) (overlay-get tip 'text))
"")
if (and (string-match re tiptext)
(overlayp tip))
collect hint
else
do (pophint--delete hint))))
(pophint--event-loop nhints cond currinputed)))
;; Select source
((and (or source-selection
(and (string-match key pophint:select-source-chars)
(eq pophint:select-source-method 'use-source-char)))
(not not-switch-source))
(pophint--debug "user inputed select source char")
(when (not source-selection) (setq inputed ""))
(let* ((currinputed (concat inputed key))
(nsource (cl-loop for src in sources
if (string= currinputed (or (assoc-default 'selector src) ""))
return src)))
(if (not nsource)
(pophint--event-loop hints cond currinputed t)
(pophint--deletes hints)
(setf (pophint--condition-source cond) nsource)
(pophint--let-user-select cond))))
;; Switch source
((and (or (string= key pophint:switch-source-char)
(string= key pophint:switch-source-reverse-char))
(not not-switch-source))
(pophint--debug "user inputed switch source")
(if (eq pophint:select-source-method 'use-popup-char)
(pophint--event-loop hints cond "" t)
(cl-loop with reverse = (string= key pophint:switch-source-reverse-char)
do (setf (pophint--condition-source cond)
(pophint--get-next-source (pophint--condition-source cond) sources reverse))
while (and pophint:switch-source-delay
(string= key (pophint--menu-read-key-sequence
(pophint--make-prompt cond (length hints))
(pophint--condition-use-pos-tip cond)
pophint:switch-source-delay))))
(pophint--deletes hints)
(pophint--let-user-select cond)))
;; Switch direction
((and (or (string= key pophint:switch-direction-char)
(string= key pophint:switch-direction-reverse-char))
(not not-switch-direction))
(pophint--debug "user inputed switch direction")
(pophint--deletes hints)
(let* ((reverse (string= key pophint:switch-direction-reverse-char))
(ndirection (cl-case (pophint--condition-direction cond)
(forward (if reverse 'around 'backward))
(backward (if reverse 'forward 'around))
(around (if reverse 'backward 'forward))
(t 'around))))
(setf (pophint--condition-direction cond) ndirection)
(pophint--let-user-select cond)))
;; Switch window
((and (string= key pophint:switch-window-char)
(not not-switch-window))
(pophint--debug "user inputed switch window")
(pophint--deletes hints)
(let* ((nwindow (pophint--get-next-window window))
(nsources (when (not not-switch-source)
(pophint--set-selector-sources (pophint--get-available-sources nwindow)))))
(setf (pophint--condition-window cond) nwindow)
;; (when (and (> (length nsources) 0)
;; (not (member source nsources)))
;; (setf (pophint--condition-source cond) nil))
(setf (pophint--condition-sources cond) nsources)
(pophint--let-user-select cond)))
;; Warning
(t
(pophint--debug "user inputed worthless char")
(pophint--show-message "Inputed not hint char.")
(sleep-for 2)
(pophint--event-loop hints cond inputed source-selection))))
;; Pass inputed command
((commandp binding)
(pophint--debug "user inputed command : %s" binding)
(pophint--deletes hints)
(call-interactively binding)
nil)
;; Abort
(t
(pophint--deletes hints))))))
(yaxception:catch 'error e
(pophint--deletes hints)
(setq pophint--last-hints nil)
(pophint--error "failed event loop : %s\n%s" (yaxception:get-text e) (yaxception:get-stack-trace-string e))
(yaxception:throw e))))
;;;;;;;;;;;;;;;;;;;;
;; For pos-tip.el
(defun pophint--pos-tip-show (string)
(copy-face 'pophint:pos-tip-face 'pos-tip-temp)
(when (eq (face-attribute 'pos-tip-temp :font) 'unspecified)