build.gradle

buildscript {
    repositories {
        maven { url 'https://plugins.gradle.org/m2/' }
    }
    dependencies {
    	classpath 'com.jfrog.bintray.gradle:gradle-bintray-plugin:1.8.4'
        classpath 'it.gianluz:gradle-capsule-plugin:1.0.3'
    }
}

plugins {
    id 'org.starchartlabs.flare.multi-module-library' version '1.0.0'
}

allprojects {
    apply plugin: 'eclipse'

    // Always download sources, to allow debugging
    eclipse {
        classpath {
            downloadSources = true
            downloadJavadoc = true
        }
    }

    repositories {
        mavenCentral()
    }
}

subprojects {
    apply plugin: 'java-library'
    apply plugin: 'checkstyle'
    apply plugin: 'jacoco'
    apply plugin: 'maven-publish'
    apply plugin: 'com.jfrog.bintray'
    
    projectMetaData {
        github {
            repository 'StarChart-Labs', 'helsing'
        }
        
        licenses {
            mit()
        }
    }

    checkstyle {
        configFile = rootProject.file('config/checkstyle/checkstyle.xml')
        configProperties = [ 'checkstyle.config.dir' : rootProject.file('config/checkstyle') ]
        toolVersion = '8.29'
    }
     
    task checkstyleAll{}
     
    tasks.withType(Checkstyle).all { checkstyleTask -> checkstyleAll.dependsOn checkstyleTask }
     
    check.dependsOn checkstyleAll

    // Setup default test behavior, including failure logging
    test {
        useTestNG() {
            useDefaultListeners = true
        }
    }
    
    // Apply module naming to all projects
    // Add LICENSE so it is included in all JARs, as well as dependent licenses, fulfilling the "distributions include license" requirement
    jar {
		manifest {
			attributes("Automatic-Module-Name": "${project.group}.${project.name  - 'helsing-'}".replaceAll("-", "."))
		}
	}
    
    tasks.withType(Jar).all {
        from("${rootDir}"){
            include 'LICENSE'
        }
    }
	
	publishing {
        publications {
            maven(MavenPublication) {
                from components.java
            }
        }
    }
    
    // If not a remote run, publish to local only
    if(!project.hasProperty('remoteDeploy')){
        publishing {
            repositories {
                mavenLocal()
            }
        }
    }

    bintray {
        publications = [ 'maven' ]

        if(!project.hasProperty('remoteDeploy')){
            dryRun = true
        }

        pkg {
            repo = 'helsing'
            name = "${project.name}"
            userOrg = 'starchart-labs'
            licenses = ['MIT']
            vcsUrl = "${projectMetaData.scm.vcsUrl}"

            version {
                name = "${project.version}"
                desc = "${project.name} release ${project.version} final"
                released  = new Date()
                vcsTag = "${project.version}"

                gpg {
                    sign = true
                }
            }
        }
	}
    
    // TODO romeara workaround until deferred credential reading is available in flare-plugins
    bintrayUpload {
        doFirst {
            user = "${credentials.bintray.username}"
            apiKey = "${credentials.bintray.password}"
        }
    }
}