build.gradle

buildscript {
    repositories {
        jcenter()
        maven {
            name = "forge"
            url = "http://files.minecraftforge.net/maven"
        }
    }
    dependencies {
        classpath "net.minecraftforge.gradle:ForgeGradle:2.3-SNAPSHOT"
    }
}
apply plugin: "net.minecraftforge.gradle.forge"

def mod_file = getModFile()
version = getModField("VERSION", mod_file)
def llibrary_version = getModField("LLIBRARY_VERSION", mod_file)
group = "net.gegy1000"
archivesBaseName = "statue"
sourceCompatibility = targetCompatibility = "1.8"

minecraft {
    version = "1.12.2-14.23.3.2655"
    runDir = "minecraft"
    mappings = "snapshot_20180510"
}

repositories {
	mavenCentral()
	maven {
		url = "https://maven.mcmoddev.com"
	}
}

dependencies {
    compile "net.ilexiconn:llibrary:$llibrary_version-1.12.2:dev"
}

processResources {
    inputs.property "version", project.version
    inputs.property "llibrary_version", llibrary_version
    from (sourceSets.main.resources.srcDirs) {
        include "mcmod.info"
         expand "version": project.version, "mcversion": project.minecraft.version, "llibrary_version": llibrary_version
    }
    from (sourceSets.main.resources.srcDirs) {
        exclude "mcmod.info"
    }
}

String getModFile() {
  String path = ""
  FileTree tree = fileTree(dir: 'src/main/java')
  tree.include '**/*.java'
  tree.visit { element ->
    if (element.file.isFile()) {
      element.file.eachLine { String s ->
        s = s.trim()
        if (s.matches("@Mod\\s*\\(.*")) {
          path = "src/main/java/$element.relativePath"
        }
      }
    }
  }
  return path
}

String getModField(String type, String mod_file) {
  if (mod_file.length() == 0) {
    return ""
  }
  String field = ""
  String prefix = "public static final String $type = \""
  File file = file(mod_file)
  file.eachLine { String s ->
    s = s.trim()
    if (s.startsWith(prefix)) {
      s = s.substring(prefix.length(), s.length() - 2)
      field = s
    }
  }
  return field
}