build.gradle

plugins {
    id 'com.github.johnrengelman.shadow' version '7.1.0' apply false
}

allprojects {
    apply plugin: 'java-library'
    apply plugin: 'com.github.johnrengelman.shadow'
    group = 'dev.rosewood'
    version = '1.0.0-SNAPSHOT'

    java {
        toolchain.languageVersion.set(JavaLanguageVersion.of(17))
    }

    repositories {
        mavenCentral()

        maven { url = 'https://libraries.minecraft.net' }
        maven { url = 'https://repo.rosewooddev.io/repository/public/' }
        maven { url = 'https://repo.aikar.co/content/groups/aikar/' }
        maven { url = 'https://repo.extendedclip.com/content/repositories/placeholderapi/' }
        maven { url = 'https://repo.dmulloy2.net/nexus/repository/public/' }
        maven { url = 'https://hub.spigotmc.org/nexus/content/repositories/snapshots/' }
    }
}

dependencies {
    implementation project(':Plugin')
    implementation project(':NMS:Wrapper')
    implementation project(path: ':NMS:v1_19_R3', configuration: 'remapped')
}

shadowJar {
    archiveClassifier.set(null)

    relocate('dev.rosewood.rosegarden', 'dev.rosewood.rosedisplays.lib.rosegarden')
    relocate('net.jodah.expiringmap', 'dev.rosewood.rosedisplays.lib.expiringmap')
    relocate('org.intellij', 'dev.rosewood.rosedisplays.lib.intellij')
    relocate('org.jetbrains', 'dev.rosewood.rosedisplays.lib.jetbrains')
    relocate('net.coobird.thumbnailator', 'dev.rosewood.rosedisplays.lib.thumbnailator')
    relocate('org.apache', 'dev.rosewood.rosedisplays.lib.apache')
}

build.dependsOn shadowJar