build.gradle

plugins {
    id 'com.gradle.plugin-publish' version "0.21.0"
    id 'java-gradle-plugin'
    id 'maven-publish'
}

sourceCompatibility = 11

repositories {
    mavenLocal()
    mavenCentral()
}

dependencies {
    testImplementation group: 'junit', name: 'junit', version: '4.12'
    implementation 'com.societegenerale.commons:arch-unit-build-plugin-core:3.0.0'
}

task sourceJar(type: Jar) {
    classifier "sources"
    from sourceSets.main.allJava
}

task javadocJar(type: Jar, dependsOn: javadoc) {
    classifier "javadoc"
    from javadoc.destinationDir
}

javadoc.options.addStringOption('Xdoclint:none', '-quiet')

artifacts {
    archives jar
    archives sourceJar
    archives javadocJar
}


gradlePlugin {
    plugins {
        archUnitGradlePlugin {
            id = 'com.societegenerale.commons.arch-unit-gradle-plugin'
            implementationClass = 'com.societegenerale.commons.plugin.gradle.ArchUnitGradlePlugin'
        }
    }
}

pluginBundle {
    website = 'https://github.com/societe-generale/arch-unit-gradle-plugin'
    vcsUrl = 'https://github.com/societe-generale/arch-unit-gradle-plugin'
    description = 'A Gradle plugin to run packaged ArchUnit rules'
    tags = ['archUnit']

    plugins {
        archUnitGradlePlugin {
            // id is captured from java-gradle-plugin configuration
            displayName = 'A Gradle plugin to run packaged ArchUnit rules'
        }
    }
}