build.gradle

plugins {
    id 'java'
    id 'application'
    id 'org.openjfx.javafxplugin'      version '0.0.10'
    id 'org.beryx.jlink'               version '2.24.0'
}

application {
    mainModule = 'fx2048'
    mainClass = 'io.fxgame.game2048.AppLauncher'
}

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of('17')
    }
}

javafx {
    version = '16'
    modules = [
       'javafx.base',
       'javafx.graphics',
       'javafx.controls'
    ]
}

// set jpackage installerType based on OS
def os = org.gradle.internal.os.OperatingSystem.current()
def pkgType = os.windows ? 'msi' : os.linux ? 'deb' : 'pkg'

jlink {
    options = ['--strip-debug', '--compress', '2', '--no-header-files', '--no-man-pages']

    imageZip = project.file("${buildDir}/distributions/game2048-${javafx.platform.classifier}.zip")

    launcher {
        name = 'fx2048'
        noConsole = true
    }

    jpackage {
        imageName = 'fx2048'
        imageOptions = []
        if (os.macOsX) {
            imageOptions += ['--mac-package-identifier','fx2048']
        }

        installerName = 'fx2048'
        installerType = "${pkgType}"
        installerOptions = ['--resource-dir', "src/main/resources"]
        installerOptions += [
                '--vendor', 'Bruno Borges',
                '--app-version', '1.0'
        ]

        if (os.windows) {
            installerOptions += ['--win-per-user-install', '--win-dir-chooser', '--win-menu']
        }

        if (os.macOsX) {
            installerOptions += ["--mac-package-name", "fx2048"]
            // Code Signing
            // installerOptions += ['--mac-sign', '--mac-signing-keychain', '/Users/bruno/certificates.p12', '--mac-signing-key-user-name', 'Bruno Borges']
        }
        skipInstaller = false
    }

}

/*
task deletePostInstall {
    print("deltePostInstall")
    // delete 'uglyFolder', 'uglyFile'
}

tasks.named("jpackageImage") { 
    finalizedBy deletePostInstall
}
*/

tasks.named("jpackageImage") {
    dependsOn jlinkZip
}

task dist {
    dependsOn clean, jpackage
    description "Calls clean and then jpackage [default]"
}

defaultTasks 'dist'