build.gradle

buildscript {
	repositories {
		mavenCentral()
		maven {
			name = "forge"
			url = "http://files.minecraftforge.net/maven"
		}
		maven {
			name = "sonatype"
			url = "https://oss.sonatype.org/content/repositories/snapshots/"
		}
	}
	dependencies {
		classpath 'net.minecraftforge.gradle:ForgeGradle:1.2-SNAPSHOT'
	}
}

ext.configFile = file "build.properties"

configFile.withReader {
	def prop = new Properties()
	prop.load(it)
	project.ext.config = new ConfigSlurper().parse prop
}

configurations {
	deployerJars
}

apply plugin: 'scala'
apply plugin: 'forge'


version				= config.mod_ver
group				= config.mod_group
archivesBaseName	= config.mod_name

sourceCompatibility = 1.8
targetCompatibility = 1.8

minecraft {
	version = "${config.mc_ver}-${config.forge_ver}"
	runDir = "eclipse"

	// Replace stuffs in the source
    replace "@VERSION@", config.mod_ver
    replace "@MC_VERSION@", config.mc_ver
}

repositories {
	mavenCentral()
	mavenLocal()
}

dependencies {
	compile files('jars/LambdaLib-PluginLoader.jar') // Core plugin loader
	deployerJars "org.apache.maven.wagon:wagon-ftp:2.2"
}

sourceSets.main {
    java.srcDirs = []
    scala.srcDirs =  ['src/main/java', 'src/main/scala']
}

task sourcesJar(type: Jar) {
    from sourceSets.main.java
    from sourceSets.main.scala
    classifier = 'sources'
}

processResources
{
	from(sourceSets.main.resources.srcDirs) {
		include 'mcmod.info'
		expand 'version':project.version, 'mcversion':project.minecraft.version
	}

	from(sourceSets.main.resources.srcDirs) {
		exclude 'mcmod.info'
	}
}

compileJava.options.encoding = "UTF-8"
compileScala.options.encoding = "UTF-8"

jar {
	manifest {
		attributes 'FMLCorePluginContainsFMLMod' : 'true'
		attributes 'FMLCorePlugin' : 'cn.lambdalib.core.LLCorePlugin'
	}
}

task deobfJar(type: Jar, dependsOn: 'jar') {
	classifier 'dev'
	from sourceSets.main.output
	manifest {
		attributes 'FMLCorePluginContainsFMLMod' : 'true'
		attributes 'FMLCorePlugin' : 'cn.lambdalib.core.LLCorePlugin'
	}
}

artifacts {
	archives deobfJar
}

install.dependsOn build