build.gradle

///////////////////////////////////////////////////////////////////////////////
//
// Build Script for building aggregated JavaPOS library from 
// JavaPOS Contracts, JavaPOS Controls, and JCL libraries
// 
// Author: denis.kuniss@dieboldnixdorf.com
// 
///////////////////////////////////////////////////////////////////////////////

plugins {
	id 'java-library'
	id 'signing'
	id 'eclipse'
    id 'maven-publish'
    id("io.github.gradle-nexus.publish-plugin") version "1.1.0"
	id 'project-report'
}

wrapper {
	gradleVersion = '8.4'
}


///////////////////////////////////////////////////////////////////////////////
// Names and Versions
///////////////////////////////////////////////////////////////////////////////

def artifactName = 'javapos'
group='org.javapos'
def uposVersion = '1.15'
version="${uposVersion}.2" // the last part after dot is the build/release version

// dependency versions
def javaposContractsVersion = "$uposVersion.2"
def javaposControlsVersion  = "$uposVersion.0"
def jclVersion = '3.1.0'
def xercesVersion = '1.2.3'  // artificial dependency inherited from javapos-config-loader - take over from there

///////////////////////////////////////////////////////////////////////////////
// Build Dependencies
///////////////////////////////////////////////////////////////////////////////

repositories {
    mavenCentral()

    // for resolving snapshots from MavenCentral if not going for a real release
    if (!isReleaseRun()) 
    {
   		logger.warn("WARN: Seems not to be a release, so Maven Central snapshot repository is fetched!");
	    maven {
	        url 'https://oss.sonatype.org/content/repositories/snapshots'
	    }
    }

    if (!System.getenv('CI')) {
        mavenLocal()
    }
}

// this gets true if Github Actions workflow defines github.event.action project variable at Gradle command line
// AND the event action is 'released' (see release.yml)
def boolean isReleaseRun() {
	return System.getenv('CI') && null != findProperty('github.event.action') && 'released'.equals(getProperty('github.event.action')) 
}

// check whether github.event.action is defined on CI
if (System.getenv('CI') && null == findProperty('github.event.action'))
	logger.warn('WARN: Project property github.event.action is not defined, so, it cannot be determined whether a release is ongoing.')

configurations {
	javaposLibs
	javaposSources
}

dependencies {
    api "xerces:xerces:$xercesVersion" // artificial dependency inherited from javapos-config-loader

	javaposLibs ("org.javapos:javapos-contracts:$javaposContractsVersion") { transitive = false } 
	javaposLibs ("org.javapos:javapos-controls:$javaposControlsVersion") { transitive = false }
	javaposLibs ("org.javapos:javapos-config-loader:$jclVersion") { transitive = false }
	
	javaposSources ("org.javapos:javapos-contracts:$javaposContractsVersion:sources") { transitive = false } 
	javaposSources ("org.javapos:javapos-controls:$javaposControlsVersion:sources") { transitive = false }
	javaposSources ("org.javapos:javapos-config-loader:$jclVersion:sources") { transitive = false }
}


///////////////////////////////////////////////////////////////////////////////
// Build Tasks
///////////////////////////////////////////////////////////////////////////////

java {
    withSourcesJar()
    withJavadocJar()
    sourceCompatibility = JavaVersion.VERSION_1_8
}

def javaposManifest = java.manifest {
        attributes('Specification-Title': 'UnifiedPOS Standard',
				   'Specification-Vendor': 'UnifiedPOS Committee',
                   'Specification-Version': uposVersion,
                   'Implementation-Title': 'JavaPOS Library (Contracts, Controls, JCL)',
				   'Implementation-Vendor': 'github.com/JavaPOSWorkingGroup',
                   'Implementation-Version': version)
}

def changelogFile = file('build/CHANGELOG.md')
task createChangelog {
    group = 'build'
    description = 'creates CHANGELOG.md, listing incoprorated JavaPOS libraries'
    
    // ensure jar is rebuild in case project version has changed
    inputs.property 'javaposContractsVersion', javaposContractsVersion 
    inputs.property 'javaposControlsVersion', javaposControlsVersion 
    inputs.property 'jclVersion', jclVersion 

    doLast {
        changelogFile.parentFile.mkdirs()
        changelogFile.text = 
"""\
# JavaPOS Library $version

Incorporates sub component versions

- javapos-contracts-$javaposContractsVersion
- javapos-controls-$javaposControlsVersion
- javapos-config-loader-$jclVersion
"""
    }
}

def jarContentFrom = { configuration -> 
    copySpec {
        configuration.each {
            def dependencyName = it.name.replace('.jar', '')
            from(zipTree(it)) {
                exclude 'META-INF/MANIFEST.MF'
                rename 'CHANGELOG.md', "${dependencyName}.CHANGELOG.md" 
            }
        }
        
        from (changelogFile) {
            into 'META-INF' 
        }
    }
}

jar {
	archiveBaseName = artifactName
	manifest = javaposManifest
    duplicatesStrategy = DuplicatesStrategy.FAIL
	
	dependsOn createChangelog

    // ensure jar is rebuild in case project version has changed
	inputs.property 'version', project.version 

    with jarContentFrom(configurations.javaposLibs)
}

sourcesJar {
	manifest = javaposManifest
    duplicatesStrategy = DuplicatesStrategy.FAIL

    dependsOn createChangelog
    
    with jarContentFrom(configurations.javaposSources)
}


///////////////////////////////////////////////////////////////////////////////
// Artifact Upload
///////////////////////////////////////////////////////////////////////////////

nexusPublishing {
    repositories {
        sonatype()
    }
}

def githubProjectUrl = 'https://github.com/JavaPOSWorkingGroup/javapos'

publishing {
    publications {
        mavenJava(MavenPublication) {
            from(components.java)
            pom {
                name = artifactName
                description = 'JavaPOS Library'
                url = githubProjectUrl
                licenses {
                    license {
                        name = 'Common Public License (CPL) -- V1.0'
                        url = 'https://www.eclipse.org/legal/cpl-v10.html'
                    }
                }
                developers {
                    developer {
                        id = 'javapos'
                        name = 'JavaPOS Working Group'
                        email = 'builder@javapos.org'
                    }
                }
                scm {
                    connection = "scm:${githubProjectUrl}.git"
                    developerConnection = "scm:git:${githubProjectUrl}.git"
                    url = "${githubProjectUrl}.git"
                }
            }
        }
    }
}

signing {
    def signingKey = findProperty("signingKey")
    def signingPassword = findProperty("signingPassword")
    useInMemoryPgpKeys(signingKey, signingPassword)
    sign publishing.publications.mavenJava
}